1

我正在尝试为以下日期格式创建 SAS 信息：

“yyyy-mm-dd hh:ii:ss.SSS UTC”，例如：“2016-01-14 10:31:01.456 UTC”

我已经使用以下格式代码接近了：

PROC FORMAT;
    PICTURE MyDate other='%0Y-%0m-%0d %0H:%0M:%0s UTC' (datatype=datetime);
RUN;

不幸的是，当我尝试将其用作 INFORMAT 时，我收到错误“找不到格式 MyDate”，因为它没有被定义为信息，只是一种输出格式。

我可以尝试从以此格式创建的数据集创建信息，但由于毫秒限制，它只会创建映射到毫秒部分中时间为 0.000 的值。例如：

DATA MyInDate ;
    RETAIN FMTNAME "MyInputDate" type "I" ;
    do label = "1jan2016:00:00:00"dt to
               "2feb2016:00:00:00"dt by 1;
        start = trim(left(put(label,MyDate.)));
        output ;
    end ;
RUN;
PROC FORMAT CNTLIN=MyInDate;
RUN;

即使我能够以毫秒为单位枚举一个数据集，它也会非常大。因为我的约会可以跨越数年。

是否可以在将我的输入数据传递给信息之前截断它？我不在乎毫秒或 UTC 限定符。我无法更改输入数据。

编辑：anydtdtm.用作信息会导致空值没有错误消息。以下是使用此信息的数据步骤：

DATA WORK.ImportDatTest;
LENGTH
    'Event Time'n    8
;
FORMAT
    'Event Time'n    DATETIME25.
;
INFORMAT
    'Event Time'n       anydtdtm.
;
INFILE DATALINES DLM=','
    ;
INPUT
    'Event Time'n    : ANYDTDTM.
;
DATALINES;
2016-01-11 17:23:34.834 UTC
2016-01-11 17:23:34.834 UTC
2016-01-11 17:23:34.834 UTC
;

RUN;
4

1 回答 1

1

不幸的是，目前没有办法在 SAS 中创建图片信息。您需要将数据转换为 SAS 具有内置信息的格式，或使用函数或类似方法来格式化数据。

但是，您的格式已经是这种格式，因此您不需要创建信息。

data test;
  x="2015-10-05 10:12:24.333 UTC";
  y=input(x,anydtdtm.);
  put y= datetime17.;
run;

您当然可以在使用信息时截断数据；通过在信息中指定长度，它将截断为该长度。

这是一个使用数据线输入的示例：

data test;
  infile datalines dlm=',' dsd;
  input y :anydtdtm32.;
  put y= datetime22.3;
  datalines;
2015-10-05 10:12:24.333 UTC
2014-03-01 08:08:05.435 UTC
2013-01-01 23:02:05.445 UTC
;;;
run;
于 2016-01-14T15:48:43.917 回答