1

为什么我可以在一个按钮下完美地运行以下代码，但在表单加载下却不能？

For Each line As String In System.IO.File.ReadAllLines("c:\pos.xml")

    If line.Contains("<POS>") = True Then

        Dim tagless As String = StripTags(line)

        Dim parts As String() = tagless.Split(New Char() {","})
        Dim XVAL As Decimal = parts(0)
        Dim YVAL As Decimal = parts(1)

        'paint markers...
        Dim myBrush As New SolidBrush(Color.FromArgb(128, Color.Red))
        Dim formGraphics As System.Drawing.Graphics
        formGraphics = Me.PictureBox1.CreateGraphics()
        formGraphics.FillEllipse(myBrush, New Rectangle(XVAL - 35, YVAL - 35, 70, 70))

        myBrush.Dispose()
        formGraphics.Dispose()

    End If
Next

如果需要，这是 striptag 功能...

    Function StripTags(ByVal html As String) As String
    ' Remove HTML tags.
    Return Regex.Replace(html, "<.*?>", "")
End Function
4

1 回答 1

1

正确的绘画方式几乎没有CreateGraphics。这将绘制一些不持久的东西。当该区域无效时，例如最小化表单或将另一个表单/应用程序拖到其上，您的形状将消失。

您还应该打开Option Strict. 代码中有许多类型错误。例如，没有Rectangle构造函数采用Decimal. 这甚至不是非整数的正确类，但RectangleF也不需要小数。

核心问题是表单在表单加载事件结束时显示。因此，您的代码在表单可见之前正在运行/绘图并且没有显示任何内容。即使表单已经显示，如果用户最小化表单或在其上移动另一个窗口，您绘制的任何内容都不会保留。

' form level list to store the data
Private XY As New List(Of PointF)       ' pts

然后在表单加载事件中，读取数据并添加到列表中

For Each line As String In System.IO.File.ReadAllLines("...")
    If line.Contains("<POS>") = True Then
        Dim tagless As String = StripTags(line)

        '                                      c required under Option Strict
        Dim parts As String() = tagless.Split(New Char() {","c})
        ' convert values to single. create a PointF
        Dim ptF As New PointF(Convert.ToSingle(parts(0)), Convert.ToSingle(parts(1)))
        ' add to list
        XY.Add(ptF)
   End If
Next

接下来发生的事情应该是显示的表单和调用的绘制事件。数据在 Paint Event 中使用：

Dim rectF As RectangleF
Using myB As New SolidBrush(Color.FromArgb(128, Color.Red))
    For Each ptF As PointF In XY
        rectF = New RectangleF(ptF.X - 35, ptF.Y - 35,
                                70, 70)

        e.Graphics.FillEllipse(myB, rectF)
    Next
End Using

如果您有其他代码来添加点数据，例如按钮单击，则在添加、更改或删除数据后，使用Invalidate强制重绘：Me.Invaludate()您是在绘制表单，还是PictureBox1.Invalidate()在控件上绘制。

教训是，现在，每次需要重新绘制表单时，您的形状也将被重新绘制。

于 2016-01-14T14:43:33.140 回答