1

我正在尝试创建一个带有两个FileChooserButtons. 第一个应该帮助用户选择一个目录，因此我正在使用操作 Select_folder; 第二个是允许用户选择一个文件。

问题是我希望第二个根据用户在第一个中所做的选择来更改当前文件夹。

我最初的想法是使用 Signal.connect，如下所示：

Signal.connect(chooser1, "selection_changed", folder_changed, null)

但是，这给了我以下编译错误：

exercise4_1.gs:62.55-62.68: error: Cannot create delegate without target for instance method or closure
        Signal.connect(chooser1, "selection_changed", folder_changed, null)
                                                      ^^^^^^^^^^^^^^
Compilation failed: 1 error(s), 0 warning(s)

我还尝试根据 vala 邮件列表中的邮件通信添加 (callback)folder_changed ，但无济于事。

这是整个代码：

[indent=4]

uses
    Gtk
    GLib

class TestWindow : Window
    chooser1:Gtk.FileChooserButton
    chooser2:Gtk.FileChooserButton
    construct()

        // General characteristics of the window
        title = "File chooser"
        window_position = WindowPosition.CENTER
        destroy.connect(Gtk.main_quit)
        chooser1 = new FileChooserButton(
                                            "Choose a Folder",
                                            FileChooserAction.SELECT_FOLDER
                                            )
        chooser2 = new FileChooserButton(
                                             "Chooser a Folder",
                                             FileChooserAction.OPEN
                                             )
        chooser1.set_current_folder(Environment.get_home_dir())
        chooser2.set_current_folder(Environment.get_home_dir())

        Signal.connect(chooser1, "selection_changed", folder_changed, null)

        var box = new Gtk.Box(Gtk.Orientation.VERTICAL, 0)
        box.pack_start(chooser1, true, true,0)
        box.pack_start(chooser2, true, true,0)
        add(box)


    def folder_changed()
        var folder = chooser1.get_filename()
        chooser2.set_current_folder(folder)


init
    Gtk.init (ref args)
    var test = new TestWindow ()
    test.show_all ()
    Gtk.main ()

  1. 这当然是我对这种特殊语法缺乏了解，但由于我被卡住了，我希望能有一个指针让我摆脱它。

  2. 作为一个额外的，不太重要的一点，最佳实践是什么：拆分和缩进长行或允许它们在代码中？

4

1 回答 1

3

Gtk 的回调需要包含生成信号的对象的参数。Genie 和 Vala 还为 GLib 信号提供语法支持，使信号更易于使用。这是基于您的代码的示例：

[indent=4]
uses
    Gtk

class TestWindow:Window
    _file_chooser:FileChooserButton

    construct()
        title = "File chooser"
        window_position = WindowPosition.CENTER
        destroy.connect( Gtk.main_quit )

        var folder_chooser = new FileChooserButton(
                                         "Choose a Folder",
                                         FileChooserAction.SELECT_FOLDER
                                        )
        folder_chooser.set_current_folder( Environment.get_home_dir() )
        folder_chooser.selection_changed.connect( folder_changed )

        _file_chooser = new FileChooserButton(
                                        "Chooser a File",
                                        FileChooserAction.OPEN
                                        )
        _file_chooser.set_current_folder( Environment.get_home_dir() )

        var box = new Box( Orientation.VERTICAL, 0 )
        box.pack_start( folder_chooser, true, true, 0 )
        box.pack_start( _file_chooser, true, true, 0 )
        add( box )

    def folder_changed( folder_chooser_widget:FileChooser )
        folder:string = folder_chooser_widget.get_uri()
        _file_chooser.set_current_folder_uri( folder )

init
    Gtk.init( ref args )
    var test = new TestWindow()
    test.show_all()
    Gtk.main()

需要注意的几点：

  • 信号名称，"selection_changed"已成为folder_chooser您随后connect要使用的属性。Vala 编译器GLib.Signal在编译时进行转换
  • , FileChooserButton,folder_chooser已从类的范围中删除。现在通过作为参数传递给回调来访问它。所以定义为回调函数的参数
  • 您会注意到回调的参数需要一个FileChooser类型而不是FileChooserButton类型。这是因为selection_changed信号是then 实现的FileChooser接口的一部分。FileChooserButton这有效地提供了一种FileChooserButton以上的类型
  • 尽管_file_chooser已声明它在类的整个范围内都可用，但它只能通过使用下划线在类内访问

使用Signal.connect()更接近于 Gtk 的 C API。如果您需要这样做，则以下工作基于您的原始代码：

[indent=4]
uses
    Gtk

class TestWindow:Window
    chooser1:FileChooserButton
    chooser2:FileChooserButton
    construct()

        // General characteristics of the window
        title = "File chooser"
        window_position = WindowPosition.CENTER
        destroy.connect( Gtk.main_quit )
        chooser1 = new FileChooserButton(
                                         "Choose a Folder",
                                         FileChooserAction.SELECT_FOLDER
                                        )
        chooser2 = new FileChooserButton(
                                        "Chooser a Folder",
                                        FileChooserAction.OPEN
                                        )
        chooser1.set_current_folder( Environment.get_home_dir() )
        chooser2.set_current_folder( Environment.get_home_dir() )

        Signal.connect( 
                      chooser1, 
                      "selection_changed", 
                      (GLib.Callback)folder_changed,
                      self
                      )

        var box = new Box( Orientation.VERTICAL, 0 )
        box.pack_start( chooser1, true, true, 0 )
        box.pack_start( chooser2, true, true, 0 )
        add( box )

    [CCode( instance_pos = 2 )]
    // or [CCode( instance_pos = -1 )] to always be last
    def folder_changed( folder_chooser:Widget )
        folder:string = chooser1.get_uri()
        chooser2.set_current_folder_uri( folder )

init
    Gtk.init( ref args )
    var test = new TestWindow()
    test.show_all()
    Gtk.main()

需要注意的几点：

  • 是的，您确实需要将回调转换GLib.Callback为您在链接到的邮件中找到的
  • 您需要的实例数据是Window您为其创建的对象，因此在此处FileChooserButton更改null为self
  • Vala 会将实例数据作为第一个参数，因此要覆盖默认值，您必须使用CCode属性，即[CCode( instance_pos = 2 )]在这种情况下
  • 生成信号的对象仍应是回调函数的第一个参数，因此即使在此示例中未使用它，它也存在于定义中。这被定义为Widget类型，但您可以将其更改FileChooser为使用get_uri()调用

如您所见，对于您的代码格式问题，我更喜欢拆分长行。我不确定 Genie 是否有公认的“最佳实践”。

于 2016-01-09T18:37:18.660 回答