6

我们在应用程序日志中看到很多“ORA-00936：缺少表达式”错误。Oracle 中有没有办法确定哪些语句失败了？

我尝试查询 v$sql，但这些语句没有插入到该视图中，因为它们没有通过语法检查。

我们的 C# 应用程序使用 Linq 生成对 Oracle 数据库的查询。这使得从应用程序获取 sql 查询有点困难。我希望我能更容易地从 Oracle 那里得到它。

4

4 回答 4

7

您可以在 Oracle 中创建一个触发器，该触发器将记录所有错误（或几乎所有错误 - NO_DATA_FOUND 不被视为错误）。在下面的示例中，模式中的任何错误都记录在 TRACK_DETAIL 表中（一行错误，下一行 SQL 失败）。您可以使用序列号、日期/时间等使其更加复杂。

create table track_detail (val varchar2(4000));

create or replace procedure track (p_text IN VARCHAR2) IS
  PRAGMA AUTONOMOUS_TRANSACTION;
begin
  insert into track_detail(val)
  values (p_text);
  commit;
end;
.
/
create or replace TRIGGER log_err after servererror on schema
DECLARE
  v_temp VARCHAR2(2000) := substr(dbms_utility.format_error_stack,1,2000);
  v_num NUMBER;
  v_sql_text ora_name_list_t;
begin
  v_temp := translate(v_temp,'''','"');
  track(v_temp);
  v_num  := ora_sql_txt(v_sql_text);
  v_temp := null;
  BEGIN
    FOR i IN 1..v_num LOOP
      v_temp := v_temp || v_sql_text(i);
    END LOOP;
  EXCEPTION
    WHEN VALUE_ERROR THEN NULL;
  END;
  v_temp := translate(v_temp,''''||chr(0)||chr(10),'"');
  track(v_temp);
end;
/

完成后请记住放下（或禁用）触发器。

于 2010-08-12T23:27:09.147 回答
2

如果您可以以某种方式从应用程序代码启用 sql 跟踪（alter session set sql_trace=true），则语句将显示在数据库主机上的跟踪文件中。

于 2010-08-12T13:48:36.933 回答
1

您可以尝试在用于连接到 Oracle 的端口上使用 Wireshark 之类的东西，以查看正在发送的 SQL 语句。可能不是最好的答案——但它可能会让你更快地到达你需要去的地方。

于 2010-08-12T13:39:38.950 回答
1

试试Kris Vandermotten 博客中的 SQL 监控解决方案。

您还可以使用DataContext.Log 属性重定向日志：

using (NorthwindDataContext context = new NorthwindDataContext())
{
  context.Log = Console.Out;
}

或使用任何其他调试工具，例如LInQ to Entities Visualizer ...

于 2010-08-12T14:17:37.813 回答