0

如果可能的话，我需要帮助将数据从散列/散列引用打印到 STDOUT 或包含特定顺序的数据的文件。

我有一个使用哈希引用的 perl 例程，如下所示：

#!/usr/local/bin/perl 

use strict;
use warnings;
use File::Basename;
use Data::Dumper;
my %MyItems;

my $ARGV ="/var/logdir/server1.log";
my $mon = 'Aug';
my $day = '06';
my $year = '2010';

while (my $line = <>)
{
    chomp $line;
    if ($line =~ m/(.* $mon $day) \d{2}:\d{2}:\d{2} $year: ([^:]+):backup:/)
    {
        my $server = basename $ARGV, '.log';
        my $BckupDate="$1 $year";
        my $BckupSet =$2;

        $MyItems{$server}{$BckupSet}->{'MyLogdate'} = $BckupDate;
        $MyItems{$server}{$BckupSet}->{'MyDataset'} = $BckupSet;
        $MyItems{$server}{$BckupSet}->{'MyHost'} = $server;

        if ($line =~ m/(ERROR|backup-size|backup-time|backup-status)[:=](.+)/)
        {
            my $BckupKey=$1;
            my $BckupVal=$2;
            $MyItems{$server}{$BckupSet}->{$BckupKey} = $BckupVal;
        }
    }
}
foreach( values %MyItems ) {
     print "MyHost=>$_->{MyHost};MyLogdate=>$_->{MyLogdate};MyDataset=>$_->{MyDataset};'backup-time'=>$_->{'backup-time'};'backup-status'=>$_->{'backup-status'}\n";
}

使用转储器输出：

$VAR1 = 'server1';
$VAR2 = {
          'abc1.mil.mad' => {
                                 'ERROR' => ' If you are sure  is not running, please remove the file and restart ',
                                 'MyLogdate' => 'Fri Aug 06 2010',
                                 'MyHost' => 'server1',
                                 'MyDataset' => 'abc1.mil.mad'
                               },
          'abc2.cfl.mil.mad' => {
                                  'backup-size' => '187.24 GB',
                                  'MyLogdate' => 'Fri Aug 06 2010',
                                  'MyHost' => 'server1',
                                  'backup-status' => 'Backup succeeded',
                                  'backup-time' => '01:54:27',
                                  'MyDataset' => 'abc2.cfl.mil.mad'
                                },

          'abc4.mad_lvm' => {
                                'backup-size' => '422.99 GB',
                                'MyLogdate' => 'Fri Aug 06 2010',
                                'MyHost' => 'server1',
                                'backup-status' => 'Backup succeeded',
                                'backup-time' => '04:48:50',
                                'MyDataset' => 'abc4.mad_lvm'
                              }
        };

我希望看到的格式化输出：

MyHost=>server1;MyLogdate=>Fri Aug 06 2010;MyDataset=>abc2.cfl.mil.mad;backup-time=>Fri Aug 06 2010;backup-status=>Backup succeeded

刚刚添加（2010 年 8 月 7 日）：我正在使用的示例原始日志文件：（最近添加以更好地表示源日志）

Fri Aug 06 00:00:05 2010: abc2.cfl.mil.mad:backup:INFO: backup-set=abc2.cfl.mil.mad
Fri Aug 06 00:00:05 2010: abc2.cfl.mil.mad:backup:INFO: backup-date=20100806000004

Fri Aug 06 00:48:54 2010: abc4.mad_lvm:backup:INFO: backup-size=422.99 GB
Fri Aug 06 00:48:54 2010: abc4.mad_lvm:backup:INFO: PHASE END: Calculating backup size & checksums
Fri Aug 06 00:48:54 2010: abc4.mad_lvm:backup:INFO: backup-time=04:48:50
Fri Aug 06 00:48:54 2010: abc4.mad_lvm:backup:INFO: backup-status=Backup succeeded
Fri Aug 06 00:48:54 2010: abc4.mad_lvm:backup:INFO: Backup succeeded
4

4 回答 4

1

我花了一些时间查看您的代码，我想我已经弄清楚了。

这很难回答的原因是您无意中植入了一条红鲱鱼 - 数据转储器输出。

注意它是如何显示$VAR1 = 'server1';的，然后$VAR2 = { blah };。

你这样称呼 Dumper： print Dumper %MyItems;

问题是 Dumper 想要一个值列表来转储，因为 Perl 扁平化列表，复杂的结构必须通过引用传递。因此，您需要像这样调用 Dumper：

print Dumper \%MyItems;

这显示了整个结构。

当您之前调用 dumper 时，您无意中剥离了一层数据结构。建议的解决方案和您自己的代码正在这个剥离的结构上运行。

在这里，我使用了一些代码来处理额外的嵌套层（并使其与 Perl 5.8 兼容）：

for my $server_items ( values %MyItems ) {
    for my $record ( values %$server_items ) {

        print join ';', map { 
            # Replace non-existant values with 'undef'
            my $val = exists $record->{$_} ? $record->{$_} : 'undef';

            "'$_'=>$val"  # <-- this is what we print for each field

        } qw( MyHost MyLogdate MyDataset backup-time backup-status );

        print "\n";
    }
}

看起来您有很多问题，需要一些帮助来理解一些概念。我建议您在 Seekers of Perl Wisdom 中的 Perlmonks 上发布请求，以帮助改进您的代码。SO 非常适合聚焦问题，但 PM 更适合代码返工。

**原始答案：**

为了解决我无法复制的任何解析问题，我只是设置%MyItems了您提供的 Dumper 的输出。

您上面提到的警告与您在打印语句中的所有复杂引用和重复编码有关。我已将您的 print 语句替换为 amap以简化代码。

废话，你可能会想，一个大的连接地图并不简单。但实际上，它更简单，因为每个单独的表达单元都更小。什么更容易理解和正确？在正确和一致的庄园中更容易改变和维护什么？

print "'foo'=>$_->{foo};'bar'=>$_->{bar};boo'=>$_->{boo};'far'=>$_->{far}\n";

或者

say join ';', map {
    "'$_'=>$item->{$_}"
} qw( foo bar boo far );

在这里，您只需更改传递给的参数列表即可添加、删除或重新排列您的输出map。对于另一种风格，您需要进行大量复制/粘贴。

我在下面使用的映射有点复杂，因为它在打印值之前检查是否定义了给定的键，如果不存在则分配一个默认值。

#!perl

use strict;
use warnings;

use feature 'say';

my %MyItems = (
    'abc1.mil.mad' => {
        'ERROR' => ' If you are sure  is not running, please remove the file and restart ',
        'MyLogdate' => 'Fri Aug 06 2010',
        'MyHost' => 'server1',
        'MyDataset' => 'abc1.mil.mad'
    },

    'abc2.cfl.mil.mad' => {
        'backup-size' => '187.24 GB',
        'MyLogdate' => 'Fri Aug 06 2010',
        'MyHost' => 'server1',
        'backup-status' => 'Backup succeeded',
        'backup-time' => '01:54:27',
        'MyDataset' => 'abc2.cfl.mil.mad'
    },

    'abc3.mil.mad' => {
        'backup-size' => '46.07 GB',
        'MyLogdate' => 'Fri Aug 06 2010',
        'MyHost' => 'server1',
        'backup-status' => 'Backup succeeded',
        'backup-time' => '00:41:06',
        'MyDataset' => 'abc3.mil.mad'
    },

    'abc4.mad_lvm' => {
        'backup-size' => '422.99 GB',
        'MyLogdate' => 'Fri Aug 06 2010',
        'MyHost' => 'server1',
        'backup-status' => 'Backup succeeded',
        'backup-time' => '04:48:50',
        'MyDataset' => 'abc4.mad_lvm'
    }
);


for my $record ( values %MyItems ) {

    say join ';', map { 
        my $val = $record->{$_} // 'undef';  # defined-or requires perl 5.10 or newer.

        "'$_'=>$val"  # <-- this is what we print for each field

    } qw( MyHost MyLogdate MyDataset backup-time backup-status );

}
于 2010-08-07T07:21:21.137 回答
0

没有回答您提出的问题，但这对我来说似乎不明智。

您想要一个哈希数组而不是哈希哈希。

哈希没有排序，如果你想让它们排序，那么使用一个数组。

于 2010-08-07T08:09:33.037 回答
0

感谢大家的帮助...这对我有用。

  for my $Server(keys%MyItems){
    for my $BckupSet(keys%{$MyItems{$Server}}){
      for(sort keys%{$MyItems{$Server}{$BckupSet}}){
        print$_,'=>',$MyItems{$Server}{$BckupSet}{$_},';';
      }
      print"\n";
    }
  }
于 2010-08-10T16:49:13.473 回答
0

未经测试，但理论上应该可以工作。这将为主 MyItems 哈希的每个键打印一个输出行。如果您希望将所有内容放在一行上，则可以删除 \n 或添加其他分隔符。

foreach( values %MyItems ) {
     print "MyServer=>$_->{MyServer};MyLogdate=>$_->{MyLogdate};MyDataset=>$_->{MyDataset};backup-time=>$_->{backup-time};backup-status=>$_->{backup-status}\n";
}
于 2010-08-07T02:17:15.103 回答