6

我想为动态语言制作一个类型化的 AST。目前，我被困在处理收藏品上。这是一个有代表性的代码示例：

{-# LANGUAGE GADTs #-}
{-# LANGUAGE DataKinds #-}
{-# LANGUAGE KindSignatures #-}
{-# LANGUAGE ExistentialQuantification #-}

data Box = forall s. B s

data BinOp = Add | Sub | Mul | Div
             deriving (Eq, Show)

data Flag = Empty | NonEmpty

data List :: Flag -> * -> * where
    Nil :: List Empty a
    Cons :: a -> List f a -> List NonEmpty a

data Expr ty where
    EInt :: Integer -> Expr Integer
    EDouble :: Double -> Expr Double
--    EList :: List -> Expr List

虽然我可以构建实例List足够好的实例：

*Main> :t (Cons (B (EInt 1)) (Cons (B (EDouble 2.0)) Nil))
(Cons (B (EInt 1)) (Cons (B (EDouble 2.0)) Nil))
  :: List Box 'NonEmpty

我完全不确定如何在Exprfor中编码这种类型EList。我什至在正确的道路上吗？

4

1 回答 1

6

解决此问题的一种方法是使用运行时类型代表标记值。我在这里引导斯蒂芬妮·韦里奇。让我们举一个小例子。首先，对某些类型进行表示。这通常是通过单例构造完成的。

data Type :: * -> * where
  Int   :: Type Int
  Char  :: Type Char
  List  :: Type x -> Type [x]

SoType Int包含一个值，我也称它为Int，因为它充当类型的运行时代表Int。如果即使在单色的东西上你也能看到颜色，Int左边::是红色，Int后面Type是蓝色。

现在我们可以进行存在包装，保留实用性。

data Cell :: * where
 (:::) :: x -> Type x -> Cell

ACell是一个标记有代表其类型的运行时的值。您可以通过读取其类型标签来恢复该值的效用。事实上，由于类型是一阶结构，我们可以用一种有用的方式检查它们是否相等。

data EQ :: k -> k -> * where
  Refl :: EQ x x

typeEQ :: Type x -> Type y -> Maybe (EQ x y)
typeEQ Int Int = Just Refl
typeEQ Char Char = Just Refl
typeEQ (List s) (List t) = case typeEQ s t of
  Just Refl -> Just Refl
  Nothing -> Nothing
typeEQ _ _ = Nothing

类型代表的布尔相等是没有用的：我们需要相等测试来构建表示的类型可以统一的证据。通过产生证据的测试，我们可以写

gimme :: Type x -> Cell -> Maybe x
gimme t (x ::: s) = case typeEQ s t of
  Just Refl -> Just x
  Nothing   -> Nothing

当然，编写类型标签是一件麻烦事。但是为什么要养一只狗并自己吠叫呢？

class TypeMe x where
  myType :: Type x

instance TypeMe Int where
  myType = Int

instance TypeMe Char where
  myType = Char

instance TypeMe x => TypeMe [x] where
  myType = List myType

cell :: TypeMe x => x -> Cell
cell x = x ::: myType

现在我们可以做类似的事情

myCells :: [Cell]
myCells = [cell (length "foo"), cell "foo"]

然后得到

> gimme Int (head myCells)
Just 3

当然，如果我们不必进行单例构造并且只需对我们可能选择在运行时保留的类型进行模式匹配，这一切都会变得更加整洁。pi我希望当神秘的量词变得不那么神秘时我们会到达那里。

于 2015-12-14T14:28:51.090 回答