8

我有一个小型 Haskell Pipe，可以打印出它运行了多少次：

counterPipe :: Pipe String String IO r
counterPipe = go 0
  where
    go n = do
      await >>= yield
      let n' = succ n
      liftIO $ putStrLn $ "Chunk " ++ show n'
      go n'

一旦处理完最后一个块，我希望能够打印出一条消息，并可能执行其他任务。我该怎么做呢？

4

1 回答 1

3

通过在上游管道完成后将counterPipe输入类型更改为Maybe String并注入额外的内容，我能够使其工作：Nothing

import Pipes
import Pipes.Core (respond)
import Control.Applicative ((<*))

withEOF :: (Monad m) => Proxy a' a b' b m r -> Proxy a' a b' (Maybe b) m r
withEOF p = for p (respond . Just) <* respond Nothing

counterPipe :: Pipe (Maybe String) String IO Int
counterPipe = go 0
  where
    go n = do
        mx <- await

        case mx of
            Just x -> do
                yield x
                let n' = succ n
                liftIO $ putStrLn $ "Chunk " ++ show n'
                go n'
            Nothing -> do
                return n

finishCounter :: Int -> Pipe a b IO ()
finishCounter n = liftIO $ putStrLn $ unwords ["Finished after", show n, "chunks"]

示例驱动程序：

import qualified Pipes.Prelude as P
main = runEffect $ withEOF P.stdinLn >-> (counterPipe >>= finishCounter) >-> P.stdoutLn

我认为这种模式应该可以抽象成类似的东西

whileJust :: (Monad m) => Proxy a' a b' b m r -> Proxy a' (Maybe a) b' b m (Maybe r)

所以你可以写

withEOF P.stdinLn >-> (whileJust counterPipe >>= maybe (return ()) finishCounter) >-> P.stdoutLn

无需更改您的原始counterPipe定义；但我以前从未使用Pipes过（上面的解决方案是通过查看类型和玩 type-domino 来解决的），所以我没有设法写whileJust（签名可能太通用了，我无法弄清楚） .

于 2015-12-14T04:12:07.833 回答