2

我有一个 Esqueleto 查询，它选择所有StatusUpdates 及其各自User的 s。我想将其限制为StatusUpdateper一个User，并且StatusUpdate从当天开始 s 。

我有一个有效的 SQL 查询，我只是在努力将它变成有效的 Esqueleto。

SELECT "email", "subject"
FROM "status_update"
LEFT JOIN "user"
ON ("status_update"."user" = "user"."id")
WHERE "status_update"."id"
IN (SELECT MAX("status_update"."id") FROM "status_update" GROUP BY "status_update"."user")

到目前为止我所拥有的：

  statusUpdates <- runDB
    $ E.select
    $ E.from $ \(status_update `E.LeftOuterJoin` user) -> do

      E.on (status_update ^. StatusUpdateUser E.==. user ^. UserId)

      E.where_ ((status_update ^. StatusUpdateId) `E.in_`
        (E.subList_select $ E.from $ \(status_update) -> do
          E.groupBy (status_update ^. StatusUpdateUser)
          return (status_update ^. StatusUpdateId)))

      return
        ( status_update ^. StatusUpdateId
        , status_update ^. StatusUpdateSubject
        , status_update ^. StatusUpdateMessage
        , user ^. UserEmail
        )

…产生以下输出：

SELECT "status_update"."id", "status_update"."subject", "status_update"."message", "user"."email"
FROM "status_update"
LEFT OUTER JOIN "user"
ON "status_update"."user" = "user"."id"
WHERE "status_update"."id"
IN (SELECT "status_update2"."id" FROM "status_update" AS "status_update2" GROUP BY "status_update2"."user"); []

似乎唯一缺少的是MAX我的第二个选择中的功能。我一直试图挤进E.max_查询的不同部分，但我似乎无法使任何工作。

帮助？

4

1 回答 1

3

您可以使用并让子查询按日期和限制 1 排序，而不是使用subList_select和尝试调用。max_sub_select

这是我找到的解决方案，似乎可以解决问题：

    result <- select $ from $ \(user, status_update) -> do
        let subquery = from $ \status_update2 -> do
            where_ (status_update2 ^. StatusUpdateUser ==. user ^. UserId)
            where_ (date (status_update2 ^. StatusUpdatePosted) ==. date now)
            orderBy [desc (status_update2 ^. StatusUpdatePosted)]
            limit 1
            return (status_update2 ^. StatusUpdateId)

        where_ (status_update ^. StatusUpdateId ==. sub_select subquery)
        where_ (user ^. UserId ==. status_update ^. StatusUpdateUser)
        return
            ( status_update ^. StatusUpdateId
            , status_update ^. StatusUpdateSubject
            , status_update ^. StatusUpdateMessage
            , user ^. UserEmail
            )

生成的 SQL 是：

SELECT "status_update"."id", "status_update"."subject", "status_update"."message", "user"."email"
FROM "user", "status_update"
WHERE ("status_update"."id" = (SELECT "status_update2"."id"
    FROM "status_update" AS "status_update2"
    WHERE ("status_update2"."user" = "user"."id")
    AND (date("status_update2"."posted") = date(date(?)))
    ORDER BY "status_update2"."posted" DESC
    LIMIT 1))
AND ("user"."id" = "status_update"."user")

为了满足StatusUpdates我定义的“仅从当天开始”条件date，并now通过导入Database.Esqueleto.Internal.Sql和：

date :: SqlExpr (Value UTCTime) -> SqlExpr (Value Int)
date d = unsafeSqlFunction "date" d

now :: SqlExpr (Value UTCTime)
now = unsafeSqlFunction "date" (val "now" :: SqlExpr (Value String))

但是，“从当天开始”对您的确切含义可能有所不同（过去 24 小时，在某个时区等）。

于 2015-12-07T20:27:41.863 回答