xml - 将节点列表分成两半

Question

<xsl:for-each select="./node [position() &lt;= (count(*) div 2)]">
    <li>foo</li>
</xsl:for-each>
<xsl:for-each select="./node [count(*) div 2 &lt; position()]">
    <li>bar</li>
</xsl:for-each>

我的列表有 12 个节点，但第二个列表总是 8 个，第一个总是 4 个。我的选择有什么问题？

Answer 1

当你这样做count(*)时，当前节点是node正在处理的元素。您想要count(current()/node)或last()（首选），或者只是计算变量的中点以获得更好的性能和更清晰的代码：

<xsl:variable name="nodes" select="node"/>
<xsl:variable name="mid" select="count($nodes) div 2"/>
<xsl:for-each select="$nodes[position() &lt;= $mid]">
  <li>foo</li>
</xsl:for-each>
<xsl:for-each select="$nodes[$mid &lt; position()]">
  <li>bar</li>
</xsl:for-each>

Answer 2

您可以尝试使用last()将为您提供当前上下文大小的函数：

<xsl:for-each select="./node [position() &lt;= last() div 2]">
   <li>foo</li>
</xsl:for-each>
<xsl:for-each select="./node [last() div 2 &lt; position()]">
   <li>bar</li>
</xsl:for-each>

Answer 3

我完全不确定，但在我看来，这count(*)并没有像你想象的那样做。这计算当前节点的子节点数，而不是当前节点列表的大小。你能把它打印出来检查它是 8 还是 9 而不是 12？

用于last()获取上下文大小。

Answer 4

尝试计数（../node）。下面将使用 xsltproc XSLT 处理器在我的测试 XML 文件（带有节点元素的简单节点根）上给出正确的结果。

<xsl:for-each select="node[position() &lt;= (count(../node) div 2)]">
    ...
</xsl:for-each>
<xsl:for-each select="node[(count(../node) div 2) &lt; position()]">
    ...
</xsl:for-each>