0

我正在编写一个 XSLT，除其他外，它可以定位某些具有“名称”属性的元素，该属性的值以破折号 ('-') 开头。当找到这样的属性时，xslt 会创建一个 xsl:attribute，它的名称是出现在“name”属性的破折号之后的所有文本。

因此，例如，假设我有以下 XML 段：

<someelement>
    <json:string name="-style">display: block; white-space: pre; border: 2px     
                       solid #c77; padding: 0 1em 0 1em; margin: 1em; 
                        background-color: #fdd; color: black</json:string>
                     [... some extra elements here ...]
</someelement>

我希望它成为

<someelement style="display: block; white-space: pre; border: 2px solid #c77; 
                   padding: 0 1em 0 1em; margin: 1em; background-color: #fdd; 
                   color: black">
                 [... some extra elements here ...]
</someelement>

目前，我正在尝试以下 XSLT 的几种变体：

  <!-- Match string|number|boolean|null elements with a "name" attribute -->
  <xsl:template match="json:string[@name] | json:number[@name] | json:boolean[@name] | json:null[@name]">
    <xsl:choose>
      <xsl:when test="starts-with(@name,'-')">
        <xsl:attribute name="{substring(./[@name],2,string-length(./@name) - 1)}">
          <xsl:value-of select="."/>
        </xsl:attribute>
      </xsl:when>
      <xsl:otherwise>
        <xsl:element name="{@name}">
          <xsl:value-of select="."/>
        </xsl:element>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

具体来说，这是令我困惑的一行：

<xsl:attribute name="{substring(./[@name],2,string-length(./@name) - 1)}">

更具体地说，其中不起作用的部分是字符串长度部分。如果我用一个数字（比如 2）替换整个字符串长度部分，它就可以正常工作。

是的，我知道 substring-after 更适合我。我确实尝试了以下方法，但它也不起作用：

<xsl:attribute name="{substring-after(./[@name],'-')}">

我确定这是某种语法错误。

PS - 我正在使用 XMLSPY 进行测试。

非常感激你的帮助。

4

1 回答 1

0

我建议你这样尝试：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="*[starts-with(@name, '-')]">
    <xsl:attribute name="{substring(@name, 2)}">
        <xsl:value-of select="."/>
    </xsl:attribute>    
</xsl:template>

</xsl:stylesheet>

测试：http: //xsltransform.net/6r5Gh3g

请注意，如果不首先处理这些“特殊”元素，这将失败：http: //xsltransform.net/6r5Gh3g/1如果有可能，您还必须匹配父元素并从那里控制处理顺序：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="*[starts-with(@name, '-')]">
    <xsl:attribute name="{substring(@name, 2)}">
        <xsl:value-of select="."/>
    </xsl:attribute>    
</xsl:template>

<xsl:template match="*[*[starts-with(@name, '-')]]">
    <xsl:copy>
        <xsl:apply-templates select="*[starts-with(@name, '-')]"/>
        <xsl:apply-templates select="@*|node()[not(starts-with(@name, '-'))]"/>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

http://xsltransform.net/6r5Gh3g/3

于 2015-11-29T09:40:31.500 回答