2

我有一个非常不寻常的问题，我无法弄清楚，也无法在任何地方找到解决方案。

我编写了一个用于计算 MIPS 中浮点数的幂的代码。该算法工作正常，但最终当系统调用应该打印返回值时，它只打印 0。

以下是用于打印返回值的代码，对我来说似乎很好，我不知道出了什么问题。

mov.s $f12, $f31
li $v0, 2
syscall

我尝试在 qtSpim 中调试代码，一切似乎都运行良好，即使在系统调用时相关寄存器中的值也是正确的。

样本输出：

在此处输入图像描述

打印结果时 FP 寄存器：

寄存器中的值似乎很好，十进制的 4 * 4 = '16' 或十六进制的 '10'。

在此处输入图像描述

完整代码：

.text
main:

addi $v0,$zero,4
la $a0,enter
syscall

li $v0, 6
syscall

mtc1 $t0, $f10
add.s $f31,$f0,$f10

addi $v0,$zero,4
la $a0,enter_2
syscall

li $v0, 5
syscall

mtc1 $t0, $f10
add.s $f12,$f31,$f10 # $a0 = x
addu $a0,$v0,$zero # $a1 = n

jal exp
mtc1 $t0, $f10
add.s $f31, $f0, $f10 #Save returned value

addi $v0,$zero,4
la $a0,result
syscall

mov.s $f12, $f31
li $v0, 2
syscall

addi $v0,$zero,4
la $a0,end
syscall

addi $v0,$zero,10
syscall

exp:
mtc1 $t0, $f10
add.s $f12,$f12,$f10 # let $f12 = x;
addu $s1,$a0,$0 # let $s1 = n

li $t1, 1
mtc1 $t1, $f11
add.s $f31, $f10, $f11 # f31=r=1;
add.s $f1, $f12, $f10 # f1=p=s0;

while:
and $t3, $s1, $t1
bne $t3,$t1,if_1
mul.s $f31, $f31, $f1
if_1:
srl $s1, $s1, $t1
bne $s1, $zero, if_2
add.s $f0, $f31,$f10
jr $ra
if_2:
mul.s $f1,$f1,$f1
j while
jr $ra

.data

enter: .asciiz "\nPlease enter a number : "
enter_2: .asciiz "\nPlease enter an exponent : "
result: .asciiz "\nResult : "
end: .asciiz "\n\nThe End :)"
4

1 回答 1

2

您应该注释您的代码，特别是如果您希望其他人提供帮助。目前尚不清楚您要在某些地方做什么，以及您使用特定寄存器的目的是什么。此外，如果你真的有那些寄存器值，结果应该打印正确。

例子：

mtc1 $t0, $f10
add.s $f12,$f12,$f10 # let $f12 = x;

我认为您希望$t0在任何地方都为零（事实并非如此），但即使这样也没有任何意义，您只需将零添加到$f12. 为什么？

li $t1, 1
mtc1 $t1, $f11
add.s $f31, $f10, $f11 # f31=r=1;

这没有设置$f11为，1因为您没有将它从 int 转换为 float。另外，如果您仍然假设$f10为零（不是从零开始的），那么为什么不直接加载$f31呢？

我已经清理了一点，这似乎工作正常：

.text
main:
    addi $v0,$zero,4
    la $a0,enter
    syscall

    li $v0, 6
    syscall

    mov.s $f31,$f0

    addi $v0,$zero,4
    la $a0,enter_2
    syscall

    li $v0, 5
    syscall

    add.s $f12,$f31,$f10 # $a0 = x
    addu $a0,$v0,$zero # $a1 = n

    jal exp
    mov.s $f31, $f0  #Save returned value

    addi $v0,$zero,4
    la $a0,result
    syscall

    mov.s $f12, $f31
    li $v0, 2
    syscall

    addi $v0,$zero,4
    la $a0,end
    syscall

    addi $v0,$zero,10
    syscall

exp:
    addu $s1,$a0,$0 # let $s1 = n

    li $t1, 1
    mtc1 $t1, $f0
    cvt.s.w $f0, $f0       # f0=1, the result

while:
    and $t3, $s1, $t1
    bne $t3, $t1, not_set
    mul.s $f0, $f0, $f12   # include this power
not_set:
    mul.s $f12, $f12, $f12 # next power
    srl $s1, $s1, $t1
    bne $s1, $zero, while
    jr $ra

.data

enter: .asciiz "\nPlease enter a number : "
enter_2: .asciiz "\nPlease enter an exponent : "
result: .asciiz "\nResult : "
end: .asciiz "\n\nThe End :)"
于 2015-11-28T13:56:10.067 回答