3

我正在学习 Ratpack 并使用多种资源。我有以下在 Ratpack v0.9.18 中工作的接口和类，但在 v1.1.1 中由于 ExecControl 接口的删除而失败。

//file: src/main/groovy/app/UserService.groovy
package app
import ratpack.exec.Promise
interface UserService {
  Promise<Void> save (User user)
  Promise<List<User>> getUsers ()
}

//file: src/main/groovy/app/DefaultUserService.groovy
package app
import ratpack.exec.ExecControl
import ratpack.exec.Promise
class DefaultUserService implements UserService {
  private final List storage = []
  @Override
  Promise<Void> save (User user) {
    storage << user
    ExecControl.current ().promiseOf (null)
  }
  @Override
  Promise<List<User>> getUsers () {
    ExecControl.current ().promiseOf (storage)
  }
}

我认为用 ExecControl 更改行：

Promise.of (storage)

会起作用，但会导致

MissingMethodException: No signature of method: static ratpack.exec.Promise.of() is applicable for argument types: (java.util.ArrayList).

Promise.of () 方法需要一种 ratpack.exec.Upstream 类型。

应该如何修改上述 DefaultUserService 类以与 Ratpack v1.1.1 一起使用？

4

1 回答 1

4

Promise.of(Upstream) http://ratpack.io/manual/current/api/ratpack/exec/Promise.html#of-ratpack.exec.Upstream-是一种将某些过程的结果通知下游消费者的方法。Downstream#error(Throwable)您可以通过http://ratpack.io/manual/current/api/ratpack/exec/Downstream.html发出信号是否成功完成Downstream#success(value)

您还可以通过以下方式Promise从已知值创建一个Promise.value(value)

除了PromiseRatpack 还提供了ratpack.exec.Operation类似于 aPromise<Void>的，它表示没有返回类型的异步工作。

我整理了一个示例来演示创建异步工作表示的各种方法。

@Grab('io.ratpack:ratpack-groovy:1.1.1')

import ratpack.exec.Operation
import ratpack.exec.Promise
import ratpack.handling.Context

import ratpack.jackson.Jackson

import static ratpack.groovy.Groovy.ratpack

class User { String name }

class UserService {
    private final List<User> storage = []

    Operation save(User user) {
        storage << user
        Operation.noop()
    }

    Promise<List<User>> getUsers() {
        Promise.of { downstream -> downstream.success(storage) }
        // or
//      Promise.value(storage)
    }
}
ratpack {
    bindings {
        bindInstance new UserService()
    }
    handlers {
        get { Context ctx, UserService userService ->
            userService.getUsers()
                    .map(Jackson.&json)
                    .then(ctx.&render)
        }
        get('add/:name') { UserService userService ->
            userService.save(new User(name: pathTokens.get('name')))
                    .then { render 'User saved' }
        }
    }
}

以下是我针对此执行的一些示例 curl 命令：

$ curl localhost:5050
[]

$ curl localhost:5050/add/dan
User saved

$ curl localhost:5050/
[{"name":"dan"}]

$ curl localhost:5050/add/luke
User saved

$ curl localhost:5050/
[{"name":"dan"},{"name":"luke"}]
于 2015-11-24T02:52:44.817 回答