1

取这两个命名图：

# graph :yesterday
:Foo 
     :likes :Bar ;
     :likes :Qux .

# graph :today
:Foo
    :likes :Bar ;
    :likes :Baz .

现在假设您想找出 graph 中是否有任何三元组:yesterday不存在于 graph 中:today。你会怎么做ASK这个查询？

ASK
FROM NAMED :yesterday
FROM NAMED :today
{
    GRAPH :yesterday {
        ?s ?p ?o .
        ...
    }
}
4

1 回答 1

6

SPARQL 有两种求反操作：使用您认为最自然的一种。当我阅读问题描述时，它对我来说更像是下面的第一个，但在这种问题情况下，它们非常相似。当模式的一部分或另一部分不匹配任何内容或没有共同变量时，它们的效果会有所不同。

NOT EXISTS测试是否没有模式（也有EXISTS）。它是应用于第一个模式的每个解决方案的过滤器。它就像一个嵌套ASK，其中变量也被过滤器的传入变量替换。

PREFIX : <http://example/>
SELECT * {
  GRAPH :yesterday { ?s ?p ?o }
  FILTER NOT EXISTS { GRAPH :today { ?s ?p ?o } }
}

MINUS执行两个模式（左侧和右侧），然后返回左侧的行，其中右侧的任何地方都没有匹配的行。这是一个反连接。

PREFIX : <http://example/>
SELECT * {
  GRAPH :yesterday { ?s ?p ?o }
  MINUS { GRAPH :today { ?s ?p ?o } }
}

对于这两个我得到：

------------------------
| s    | p      | o    |
========================
| :Foo | :likes | :Qux |
------------------------

三角：

@prefix : <http://example/> .

:yesterday {
  :Foo 
     :likes :Bar ;
     :likes :Qux .
}

:today {
  :Foo
    :likes :Bar ;
    :likes :Baz .
}
于 2015-11-15T10:59:12.950 回答