20

在使用 Gradle 插件的多模块项目中，正确的 Gradle 配置是什么样spring-boot-dependencies的spring-boot？

我有以下项目设置：

parent
  |
  + build.gradle
  |
  + alpha
  |   |
  |   + build.gradle
  |
  + beta
  |   |
  |   + build.gradle
  • 该parent模块包含常见的项目配置。
  • 该alpha模块是一个模块，我想使用spring-boot-dependencies bom 中指定的版本号导入依赖项，但结果是标准 jar。
  • 该beta模块是一个依赖的模块，alpha结果是一个可执行的 Spring Boot jar 文件（包括所有依赖项）。因此，这个项目既需要插件spring-boot-dependencies也需要spring-boot插件。

为了使 Gradle 文件保持干燥，我已将常用模块脚本提取到父build.gradle文件中。

尝试$ gradle build使用以下项目配置执行会导致：

> Plugin with id 'io.spring.dependency-management' not found.

父 gradle.build

allprojects {
    group = "com.example"
    version '0.0.1-SNAPSHOT'

    ext {
        dependencyManagementPluginVersion = '0.5.3.RELEASE'
        springBootVersion = '1.3.0.RC1'
    }

    apply plugin: 'java'
    apply plugin: 'eclipse'
    apply plugin: 'idea'
}

subprojects {
    sourceCompatibility = 1.8
    targetCompatibility = 1.8

    buildscript {
        repositories {
            jcenter()
            maven { url "https://repo.spring.io/snapshot" }
            maven { url "https://repo.spring.io/milestone" }
        }
        dependencies {
            classpath("io.spring.gradle:dependency-management-plugin:${dependencyManagementPluginVersion}")
            classpath("org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}")
        }
    }

    apply plugin: 'io.spring.dependency-management'

    dependencyManagement {
        imports {
            mavenBom("org.springframework.boot:spring-boot-dependencies:${springBootVersion}")
//            mavenBom("org.springframework.boot:spring-boot-starter-parent:${springBootVersion}")
        }
    }
}

alpha build.gradle

dependencies {
    compile('org.springframework:spring-web')
}

beta gradle.build

apply plugin: 'spring-boot'

dependencies {
    compile project(':alpha')
    compile('org.springframework.boot:spring-boot-starter')
    compile('org.springframework.boot:spring-boot-starter-web')
}

注释：

  • Spring Boot 1.3.0.M1中更改spring-boot了插件的行为
  • 摇篮版本：2.8
  • Spring Boot 版本 1.3.0.RC1
4

1 回答 1

22

事实证明，parent/build.gradle应该按以下方式重新排列：

buildscript {
    ext {
        dependencyManagementPluginVersion = '0.5.3.RELEASE'
        springBootVersion = '1.3.0.RC1'
    }
    repositories {
        jcenter()
        maven { url "https://repo.spring.io/snapshot" }
        maven { url "https://repo.spring.io/milestone" }
    }
    dependencies {
        classpath("io.spring.gradle:dependency-management-plugin:${dependencyManagementPluginVersion}")
        classpath("org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}")
    }
}

allprojects {
    group = "com.example"
    version '0.0.1-SNAPSHOT'

    apply plugin: 'java'
    apply plugin: 'eclipse'
    apply plugin: 'idea'
}

subprojects {
    sourceCompatibility = 1.8
    targetCompatibility = 1.8

    apply plugin: 'io.spring.dependency-management'

    dependencyManagement {
        imports {
            mavenBom("org.springframework.boot:spring-boot-dependencies:${springBootVersion}")
//          mavenBom("org.springframework.boot:spring-boot-starter-parent:${springBootVersion}")
        }
    }
}

问题在于buildscript子项目的块确实配置得很好，但是......在错误的地方。此subprojects块与子项目相关，但将在声明它的脚本中进行评估，并且没有为它试图应用的插件声明依赖项。

于 2015-11-14T22:20:39.613 回答