0

对问题的回应是否可以将 PNG 文件导入 SAS 以包含在 RTF 输出中？提供了一种在 SAS ODS RTF 输出中使用外部 PNG 文件的方法。为了使提供的解决方案起作用，它需要文本跟随图像文件的插入。即使图像后面没有文本，我用来使它工作的一种方法是在图像后面插入下划线，这将在脚注之前有一个底部边框；但是，这不符合为该项目创建的其他输出，因此我正在寻找一种方法来导入保持基本格式的 PNG。

另外，我希望能够调整图像的显示尺寸。目前，我必须确保图像大小在创建时完全正确，以免超出边界，但这会创建一个比我想要的像素化程度更高的图像。我希望能够将其强制为 SAS 所需的大小，以便在创建图像并在 RTF 文件中生成质量足够高的图像时可以在大小上有一些灵活性。

虽然这看起来像是不同的问题，但在我看来，一个问题的解决方案可能会同时解决这两个问题，如下所示。

这是一些生成最小示例的代码：

/* Create test data */
data test;
  drop i;
  call streaminit(1579);
  do i = 1 to 200;
    u = rand("Normal");
    output;
  end;
run;

/* Create a PNG file to bring into the RTF -- the PNG will
   actually be created outside of SAS but is included here
   for convenience */
proc sgplot data=test;
  density u / type=kernel;
run;

/* Set options for RTF output */
option nodate nonumber;
ods rtf file = "test.rtf" nogtitle nogfoot
ods escapechar='~';

/* Titles and footnotes */
title 'Title';
/* Border line at the start of the footnote section */
footnote height=2pt '~R"\brdrb\brdrs\brdrw30';
footnote2 j=l 'Footnote';

/* Import the image and output into the RTF */
ods text='~S={preimage="SGPlot1.png"}';
ods rtf close;

上面的代码生成的文档如下所示：

错误的输出

身体中那条细的垂直线就是图像。如果我将手柄向右拖动，则会出现完整的图像。我希望能够创建与以下代码等效的代码，而无需在 SAS 中创建图像：

/* Set options for RTF output */
option nodate nonumber;
ods rtf file = "test1.rtf" nogtitle nogfoot;
ods escapechar='~';

/* Titles and footnotes */
title 'Title';
/* Border line at the start of the footnote section */
footnote height=2pt '~R"\brdrb\brdrs\brdrw30';
footnote2 j=l 'Footnote';

ods graphics / height=9in width=7in;

/* Import the image and output into the RTF */
proc sgplot data=test;
  density u / type=kernel;
run;
ods rtf close;

此代码产生以下内容：

期望的输出

请注意，我已经放大了图像（SAS 在创建图像时会自动调整像素等，但这不是必需的，因为已经创建了 PNG 文件）。另请注意，图像实际上是在生成 RTF 时显示的，不需要任何后期处理。这可能吗？

4

1 回答 1

0

经过一番调查，我发现这个答案有两个部分。可以通过添加width=100%如下样式来使图像完全显示而不是没有宽度：

ods text='~S={width=100% preimage="SGPlot1.png"}';

调整图像的尺寸有点骇人听闻，但可以通过将文件作为文本读取并替换 rtf 控制字pichgoalN以及picwgoalN所需的高度和宽度（以缇为单位）来完成（缇是 1/1440 英寸） . 我是这样做的：

data edit;
  infile "test.rtf" dlm='09'x dsd lrecl=32767 missover;
  format var $200. varout $200.;
  input var $;
  varout = prxchange("s/pichgoal\d+/pichgoal12960/",-1,var);
  varout = prxchange("s/picwgoal\d+/picwgoal10080/",-1,varout);
run;

data _null_ ;
  set edit ; 
  FILE 'test1.rtf';
  PUT varout; 
run ;
于 2015-11-11T16:06:44.113 回答