1

我正在尝试执行以下操作：

bmp := TBitmap.Create;
bmp.Width := FWidth;
bmp.Height := FHeight;
for y := 0 to FHeight - 1 do
begin
   sl := bmp.ScanLine[y];
   for x := 0 to FWidth - 1 do
   begin
      //draw to the scanline, one pixel at a time
   end;
end;
//display the image
bmp.Free;

不幸的是，我最终得到的是一个完全白色的图像，除了底线，它被适当地着色。一点调试表明，每次我访问该ScanLine属性时，它都会调用TBitmap.FreeImage并进入if (FHandle <> 0) and (FHandle <> FDIBHandle) then块，这会重置整个图像，因此实际上只需要对最后一行的更改。

到目前为止，在我使用的每个演示中TBitmap.ScanLine，它们都是从加载图像开始的。（显然，这会正确设置各种句柄，这样就不会发生这种情况？）但我并没有尝试加载图像并对其进行处理；我正在尝试从相机捕获图像数据。

如何设置位图以便无需先加载图像就可以绘制到扫描线？

4

1 回答 1

2

您应该PixelFormat在开始绘制之前明确设置。例如，

procedure TForm1.FormPaint(Sender: TObject);
var
  bm: TBitmap;
  y: Integer;
  sl: PRGBQuad;
  x: Integer;
begin

  bm := TBitmap.Create;
  try
    bm.SetSize(1024, 1024);
    bm.PixelFormat := pf32bit;
    for y := 0 to bm.Height - 1 do
    begin
      sl := bm.ScanLine[y];
      for x := 0 to bm.Width - 1 do
      begin
        sl.rgbBlue := 255 * x div bm.Width;
        sl.rgbRed := 255 * y div bm.Height;
        sl.rgbGreen := 255 * x div bm.Width;
        inc(sl);
      end;
    end;

    Canvas.Draw(0, 0, bm);
  finally
    bm.Free;
  end;

end;
于 2015-11-06T20:45:04.097 回答