1

我想将加速数组转换为 repa 数组，然后使用writeImageToBMPfrom repa-io 将数组写入 BMP 文件。忽略加速 io 中存在这样一个功能的事实，我只是将其用作问题的示例。拿：

{-# LANGUAGE ScopedTypeVariables #-}
import qualified Data.Array.Accelerate.Interpreter as A (run)
import Data.Array.Accelerate
import qualified Data.Array.Accelerate as A
import qualified Data.Array.Accelerate.IO as A
import qualified Data.Array.Repa as Repa
import qualified Data.Array.Repa.IO.BMP as Repa
import GHC.Word

main :: IO ()
main = do
  let accelArr = A.fromList
                 (Z :. (2::Int) :. (1::Int))
                 ([(1,2,3),(4,5,6)] :: [(Word8,Word8,Word8)])
      computation :: A.Acc (A.Array A.DIM2 (Word8,Word8,Word8))
      computation = A.map
       (\triple ->
           let (r',g',b') = unlift triple :: (Exp Word8,Exp Word8,Exp Word8)
           in lift (constant 0,g',b')) (use accelArr)
      repaArr :: Repa.Array A.A Repa.DIM2 (Word8,Word8,Word8)
      repaArr = A.toRepa (A.run computation)
  Repa.writeImageToBMP "out_repa.bmp" repaArr

需要包加速、加速 io、repa 和 repa-io 来编译此代码。

这不会编译，因为writeImageToBmprepa-io 中的类型是：

writeImageToBMP
  :: FilePath
  -> Repa.Array Repa.U Repa.DIM2 (Word8, Word8, Word8)
  -> IO ()

whereU表示 repa 中的清单数组。GHC 错误是：

Couldn't match type ‘A.A’ with ‘Repa.U’
Expected type: Repa.Array Repa.U Repa.DIM2 (Word8, Word8, Word8)
  Actual type: Repa.Array A.A Repa.DIM2 (Word8, Word8, Word8)
In the second argument of ‘Repa.writeImageToBMP’, namely ‘repaArr’
In a stmt of a 'do' block:
  Repa.writeImageToBMP "out_repa.bmp" repaArr

的类型repaArr是：

Repa.Array A.A Repa.DIM2 (Word8,Word8,Word8)

这就是为什么 GHC 抱怨它是writeImageToBMP.

问题：如何将加速数组表示转换A为 repa 清单数组表示U，以便我可以调用writeImageToBMP它？

4

1 回答 1

2

请注意，Data.Array.Repa 中的函数computeS、computeP、copyS和copyP具有这种签名：

...constraints... => Array r1 sh e -> m (Array r2 sh e)

因此它们是允许您在不同的 Repa 表示之间进行转换的函数（即转换 r1 -> r2）。

考虑到这一点，我得到了这个代码来输入检查：

main :: IO ()
main = do
  let accelArr = A.fromList
                 (Z :. (2::Int) :. (1::Int))
                 ([(1,2,3),(4,5,6)] :: [(Word8,Word8,Word8)])
      computation :: A.Acc (A.Array A.DIM2 (Word8,Word8,Word8))
      computation = A.map
       (\triple ->
           let (r',g',b') = unlift triple :: (Exp Word8,Exp Word8,Exp Word8)
           in lift (constant 0,g',b')) (use accelArr)
      repaArr :: Repa.Array A.A Repa.DIM2 (Word8,Word8,Word8)
      repaArr = A.toRepa (A.run computation)
  zzz <- Repa.copyP repaArr
  Repa.writeImageToBMP "out_repa.bmp" zzz

你也可以Repa.copyS在这里使用。

于 2015-11-05T17:44:45.103 回答