4

我目前正在关注 om-next教程。在添加读取部分，get-people定义了一个函数。除此功能外，init-data还定义了包含人员列表的地图。

(defn get-people [state key]
  (let [st @state]
    (into [] (map #(get-in st %)) (get st key))))

(def init-data {:list/one
 [{:name "John", :points 0}
  {:name "Mary", :points 0}
  {:name "Bob", :points 0}],
 :list/two
 [{:name "Mary", :points 0, :age 27}
  {:name "Gwen", :points 0} 
  {:name "Jeff", :points 0}]})

这是我尝试调用此函数的尝试。

(get-people (atom init-data) :list/one) ;; => [nil nil nil]

如您所见，我只是返回了nils 的向量。我不太明白我应该如何调用这个函数。有人可以帮帮我吗？谢谢！

4

1 回答 1

5

好吧，我想通了。

init-data不是要调用的正确数据结构get-people。初始数据必须首先使用 Om's 进行“协调” reconciler。您可以在本教程的规范化部分找到有关协调器的更多信息。

协调init-data映射然后derefing 数据返回这个规范化的数据结构：

{:list/one
 [[:person/by-name "John"]
  [:person/by-name "Mary"]
  [:person/by-name "Bob"]],
 :list/two
 [[:person/by-name "Mary"]
  [:person/by-name "Gwen"]
  [:person/by-name "Jeff"]],
 :person/by-name
 {"John" {:name "John", :points 0},
  "Mary" {:name "Mary", :points 0, :age 27},
  "Bob" {:name "Bob", :points 0},
  "Gwen" {:name "Gwen", :points 0},
  "Jeff" {:name "Jeff", :points 0}}}

get-people这是使用协调的 init-data对函数的有效调用：

; reconciled initial data
(def reconciled-data
  {:list/one
   [[:person/by-name "John"]
    [:person/by-name "Mary"]
    [:person/by-name "Bob"]],
   :list/two
   [[:person/by-name "Mary"]
    [:person/by-name "Gwen"]
    [:person/by-name "Jeff"]],
   :person/by-name
   {"John" {:name "John", :points 0},
    "Mary" {:name "Mary", :points 0, :age 27},
    "Bob" {:name "Bob", :points 0},
    "Gwen" {:name "Gwen", :points 0},
    "Jeff" {:name "Jeff", :points 0}}}

; correct function call
(get-people (atom reconciled-data) :list/one)

; returned results
[{:name "John", :points 0}
 {:name "Mary", :points 0, :age 27}
 {:name "Bob", :points 0}]

这是正在发生的事情：

  1. 首先，该函数检索与键关联的值:list/one。在这种情况下，该值是地图中的路径向量（每条路径本身就是一个向量）。
  2. 接下来，映射路径并在每个向量上调用匿名函数。其中一个调用看起来像(get-in st [:person/by-name "John"])并返回{:name "John", :points 0}。
  3. 将结果作为向量返回

如果有人正在阅读本文并希望进一步澄清，请告诉我。

于 2015-11-03T04:30:57.473 回答