1

Grails 2.4.x 在这里。

我要求由 生成的所有 Grails 服务的所有方法都grails create-service <xyz>使用以下逻辑“包装”/拦截：

try {
    executeTheMethod()
} catch(MyAppException maExc) {
    log.error(ExceptionUtils.getStackTrace(maExc))
    myAppExceptionHandler.handleOrRethrow(maExc)
}

在哪里：

  • log.error(...)是您在使用注释对类进行注释时获得的 SLF4J 提供的记录器@Slf4j；和
  • ExceptionUtils是来自org.apache.commons:commons-lang3:3.4; 和
  • myAppExceptionHandler是类型com.example.myapp.MyAppExceptionHandler；和
  • 对于 Grails 服务中定义的每个方法，这种行为都存在（或者在需要以某种方式显式调用的情况下可以选择存在）

所以很明显，这个包装代码也需要包含import这些类的语句。

因此，例如，如果我有一个WidgetService看起来像这样的：

class WidgetService {
    WidgetDataService widgetDataService = new WidgetDataService()

    Widget getWidgetById(Long widgetId) {
        List<Widget> widgets = widgetDataService.getAllWidgets()
        widgets.each {
            if(it.id.equals(widgetId)) {
                return it
            }
        }

        return null
    }
}

然后在这个 Groovy/Grails/closure 魔术发生之后，我需要代码表现得就像我写的一样：

import groovy.util.logging.Slf4j
import org.apache.commons.lang3.exception.ExceptionUtils
import com.example.myapp.MyAppExceptionHandler

@Slf4j
class WidgetService {
    WidgetDataService widgetDataService = new WidgetDataService()

    MyAppExceptionHandler myAppExceptionHandler = new MyAppExceptionHandler()

    Widget getWidgetById(Long widgetId) {
        try {
            List<Widget> widgets = widgetDataService.getAllWidgets()
            widgets.each {
                if(it.id.equals(widgetId)) {
                    return it
                }
            }

            return null
        } catch(MyAppException maExc) {
            log.error(ExceptionUtils.getStackTrace(maExc))
            myAppExceptionHandler.handleOrRethrow(maExc)
        }
    }
}

关于我如何能够实现这一目标的任何想法？我担心纯 Groovy 闭包可能会以某种方式干扰 Grails 在运行时对其服务所做的任何事情（因为它们都是没有显式扩展父类的类）。

4

2 回答 2

2

这是我试图在评论中指出的内容：

package com.example

import groovy.util.logging.Log4j

@Log4j
trait SomeTrait {

    def withErrorHandler(Closure clos) {
        try {
            clos()
        } catch(Exception e) {
            log.error e.message
            throw new ApplicationSpecificException(
                "Application Specific Message: ${e.message}"
            )
        }
    }
}

服务等级：

package com.example

class SampleService implements SomeTrait {

    def throwingException() {
        withErrorHandler {
            throw new Exception("I am an exception")
        }
    }

    def notThrowingException() {
        withErrorHandler {
            println "foo bar"
        }
    }
}

测试：

package com.example

import grails.test.mixin.TestFor
import spock.lang.Specification

@TestFor(SampleService)
class SampleServiceSpec extends Specification {

    void "test something"() {
        when:
        service.throwingException()

        then:
        ApplicationSpecificException e = thrown(ApplicationSpecificException)
        e.message == "Application Specific Message: I am an exception"
    }

    void "test something again"() {
        when:
        service.notThrowingException()

        then:
        notThrown(Exception)
    }
}

这是示例应用程序。

Grails 3.0.9 但它应该没关系。这适用于 Grails 2.4。*

于 2015-11-02T22:20:04.700 回答
1

您可以使用 MetaInjection 或 Spring AOP 拦截对 Service 类方法的调用。因此，您不必在每个 Service 类中编写闭包。您可以查看此博客，该博客通过示例解释了这两种方法。

于 2015-10-31T12:53:12.383 回答