5

我定义了以下模块来帮助我进行 FFI 函数导出：

{-# LANGUAGE MultiParamTypeClasses, FunctionalDependencies, TypeSynonymInstances #-}
module ExportFFI where

import Foreign
import Foreign.C


class FFI basic ffitype | basic -> ffitype where
    toFFI :: basic -> IO ffitype
    fromFFI :: ffitype -> IO basic
    freeFFI :: ffitype -> IO ()

instance FFI String CString where
    toFFI = newCString
    fromFFI = peekCString
    freeFFI = free

我正在为函数的实例而苦苦挣扎。有人能帮我吗？

4

1 回答 1

6

对于涉及 FFI 的函数，您可以做两件事： 1) 编组：这意味着将函数转换为可以通过 FFI 导出的类型。这由FunPtr. 2) 导出：这意味着为非 Haskell 代码创建一个调用 Haskell 函数的方法。

您的 FFI 类有助于编组，首先我创建了一些如何编组函数的示例实例。

这是未经测试的，但它可以编译，我希望它可以工作。首先，让我们稍微改变一下类：

class FFI basic ffitype | basic -> ffitype, ffitype -> basic where
    toFFI :: basic -> IO ffitype
    fromFFI :: ffitype -> IO basic
    freeFFI :: ffitype -> IO ()

这表示给定“基本”或“ffitype”的类型，另一个是固定的[1]。这意味着不再可能将两个不同的值编组为同一类型，例如，您不能再同时拥有两者

instance FFI Int CInt where

instance FFI Int32 CInt where

这样做的原因是因为freeFFI不能像你定义的那样使用它；无法确定仅从 ffitype 中选择哪个实例。或者，您可以将类型更改为freeFFI :: ffitype -> basic -> IO (), 或 (更好？) freeFFI :: ffitype -> IO basic。那么你根本不需要基金。

分配 FunPtr 的唯一方法是使用“外部导入”语句，该语句仅适用于完全实例化的类型。您还需要启用ForeignFunctionInterface扩展。因此toFFI，应该返回 a 的函数IO (FunPtr x)不能在函数类型上具有多态性。换句话说，你需要这个：

foreign import ccall "wrapper"
  mkIntFn :: (Int32 -> Int32) -> IO (FunPtr (Int32 -> Int32))

foreign import ccall "dynamic"
  dynIntFn :: FunPtr (Int32 -> Int32) -> (Int32 -> Int32)

instance FFI (Int32 -> Int32) (FunPtr (Int32 -> Int32)) where
    toFFI = mkIntFn
    fromFFI = return . dynIntFn
    freeFFI = freeHaskellFunPtr

对于您要编组的每种不同的函数类型。您还需要FlexibleInstances此实例的扩展名。FFI 施加了一些限制：每种类型都必须是可编组的外部类型，函数返回类型必须是可编组的外部类型或返回可编组的外部类型的 IO 操作。

对于不可编组的类型（例如字符串），您需要稍微复杂一些的东西。首先，由于编组发生在 IO 中，您只能编组导致 IO 操作的函数。如果要编组纯函数，例如 (String -> String)，则需要将它们提升为 (String -> IO String) 形式。 [2] 让我们定义两个助手：

wrapFn :: (FFI a ca, FFI b cb) => (a -> IO b) -> (ca -> IO cb)
wrapFn fn = fromFFI >=> fn >=> toFFI

unwrapFn :: (FFI a ca, FFI b cb) => (ca -> IO cb) -> (a -> IO b)
unwrapFn fn a = bracket (toFFI a) freeFFI (fn >=> fromFFI)

这些将函数的类型转换为适当的编组值，例如wrapStrFn :: (String -> IO String) -> (CString -> IO CString); wrapStrFn = wrapFn. 请注意，unwrapFn使用“Control.Exception.bracket”来确保在发生异常时释放资源。忽略这一点，你可以写unwrapFn fn = toFFI >=> fn >=> fromFFI；查看与 wrapFn 的相似性。

现在我们有了这些助手，我们可以开始编写实例了：

foreign import ccall "wrapper"
  mkStrFn :: (CString -> IO CString) -> IO (FunPtr (CString -> IO CString))

foreign import ccall "dynamic"
  dynStrFn :: FunPtr (CString -> IO CString) -> (CString -> IO CString)

instance FFI (String -> IO String) (FunPtr (CString -> IO CString)) where
    toFFI = mkStrFn . wrapFn
    fromFFI = return . unwrapFn . dynStrFn
    freeFFI = freeHaskellFunPtr

和以前一样，不可能使这些函数多态，这导致我对这个系统最大的保留。这是很多开销，因为您需要为每种类型的函数创建单独的包装器和实例。除非您要进行大量功能编组，否则我会严重怀疑是否值得付出努力。

这就是你可以编组函数的方式，但是如果你想让它们可用于调用代码怎么办？另一个过程是导出函数，我们已经开发了大部分必要的东西。

导出的函数必须具有可编组的类型，就像FunPtrs. 我们可以简单地重复使用wrapFn来做到这一点。要导出一些函数，您需要做的就是用它们包装wrapFn并导出包装后的版本：

f1 :: Int -> Int
f1 = (+2)

f2 :: String -> String
f2 = reverse

f3 :: String -> IO Int
f3 = return . length

foreign export ccall f1Wrapped :: CInt -> IO CInt
f1Wrapped = wrapFn (return . f1)

foreign export ccall f2Wrapped :: CString -> IO CString
f2Wrapped = wrapFn (return . f2)

foreign export ccall f3Wrapped :: CString -> IO CInt
f3Wrapped = wrapFn f3

不幸的是，此设置仅适用于单参数函数。为了支持所有功能，让我们创建另一个类：

class ExportFunction a b where
  exportFunction :: a -> b

instance (FFI a ca, FFI b cb) => ExportFunction (a->b) (ca -> IO cb) where
  exportFunction fn = (wrapFn (return . fn))

instance (FFI a ca, FFI b cb, FFI d cd) => ExportFunction (a->b->d) (ca->cb->IO cd) where
  exportFunction fn = \ca cb -> do
    a <- fromFFI ca
    b <- fromFFI cb
    toFFI $ fn a b

现在我们可以使用exportFunction带有 1 个和 2 个参数的函数：

f4 :: Int -> Int -> Int
f4 = (+)

f4Wrapped :: CInt -> CInt -> IO CInt
f4Wrapped = exportFunction f4

foreign export ccall f4Wrapped :: CInt -> CInt -> IO CInt

f3Wrapped2 = :: CString -> IO CInt
f3Wrapped2 = exportFunction f3

foreign export ccall f3Wrapped2 :: CString -> IO CInt
f3Wrapped2 = exportFunction f3

现在您只需要编写更多的实例ExportFunction来自动将任何函数转换为适当的类型以进行导出。我认为这是最好的，无需使用某种类型的预处理器或 unsafePerformIO。

[1] 从技术上讲，我认为不需要“basic -> ffitype”fundep，因此您可以删除它以使一种基本类型能够映射到多个 ffitype。这样做的一个原因是将所有大小的整数映射到整数，尽管toFFI实现会是有损的。

[2] 略微简化。您可以将函数编组为String -> StringFFI 类型的CString -> IO CString. 但是现在由于返回类型中的 IO，您无法将CString -> IO CString函数转换回。String -> String

于 2010-07-28T00:20:46.043 回答