0

我正在玩基于 ocamllex 和 ocamlyacc 的 FsLex 和 FsYacc。用语言定义评论的最佳方式是什么？我是否在我的 lex 文件中创建注释标记？在语法的上下文中，我无法理解的评论有一些复杂性：

  1. 注释可以放在语法中的任何地方，应该被忽略。
  2. 注释可以包含任何内容，包括其他标记和无效代码。
  3. 注释可以跨越多行，我需要维护调试器的源代码位置。在 FsLex 和 ocamllex 中，这必须由语言开发人员完成。
4

1 回答 1

2

由于您包含ocaml我将回答的标签ocamllex。

确实，处理注释很困难，特别是如果您的语言希望能够注释掉代码段。在这种情况下，注释词法分析器必须在注释中寻找（减少的）标记，以免被引用上下文中出现的注释闭包所迷惑。这也意味着词法分析器应该遵循注释的嵌套，因此注释掉的注释不会混淆事物。

OCaml 编译器本身就是这种方法的一个例子。OCaml 编译器的注释处理包含三个部分。第一级词法规则如下所示：

rule main = parse

    . . . code omitted here . . .

    | "(*"
      { comment_depth := 1;
        handle_lexical_error comment lexbuf;
        main lexbuf }

第二层由功能handle_lexical_error和功能组成comment。前者在捕获特定异常的同时评估词法分析函数。后者是用于注释的详细词法分析功能。在对注释进行词法分析之后，上面的代码会返回到常规词法分析（使用main lexbuf）。

该函数comment如下所示：

rule comment = parse
    "(*"
    { incr comment_depth; comment lexbuf }
  | "*)"
    { decr comment_depth;
      if !comment_depth = 0 then () else comment lexbuf }
  | '"'
    { reset_string_buffer();
      string lexbuf;
      reset_string_buffer();
      comment lexbuf }
  | "'"
    { skip_char lexbuf ;
     comment lexbuf }
  | eof
    { raise(Lexical_error("unterminated comment", "", 0, 0)) }
  | '\010'
    { incr_loc lexbuf 0;
      comment lexbuf }
  | _
    { comment lexbuf }

所以，是的，做好工作是相当复杂的。

最后一点，ocamllex自动为您跟踪源代码位置。您可以从 lexbuf 中检索它们。请参阅 OCamlLexing模块。（但是，请注意，上面的注释词法分析函数会在对换行符进行词法分析时调整位置。该incr_loc函数会增加跟踪的行号。）

我不确定 F# 与此设计的密切程度，但希望这会有所帮助。

更新

这是string词法分析功能：

rule string = parse
    '"'
    { () }
   | '\\' ("\010" | "\013" | "\013\010") ([' ' '\009'] * as spaces)
    { incr_loc lexbuf (String.length spaces);
      string lexbuf }
  | '\\' (backslash_escapes as c)
    { store_string_char(char_for_backslash c);
      string lexbuf }
  | '\\' (['0'-'9'] as c) (['0'-'9'] as d) (['0'-'9']  as u)
    { let v = decimal_code c d u in
      if in_pattern () && v > 255 then
       warning lexbuf
        (Printf.sprintf
          "illegal backslash escape in string: `\\%c%c%c'" c d u) ;
      store_string_char (Char.chr v);
      string lexbuf }
 | '\\' 'x' (['0'-'9' 'a'-'f' 'A'-'F'] as d) (['0'-'9' 'a'-'f' 'A'-'F'] as u)   
    { store_string_char (char_for_hexadecimal_code d u) ;
      string lexbuf }
  | '\\' (_ as c) 
    {if in_pattern () then
       warning lexbuf
        (Printf.sprintf "illegal backslash escape in string: `\\%c'" c) ;
      store_string_char '\\' ;
      store_string_char c ;
      string lexbuf }
  | eof
    { raise(Lexical_error("unterminated string", "", 0, 0)) }
  | '\010'
    { store_string_char '\010';
      incr_loc lexbuf 0;
      string lexbuf }
  | _ as c
    { store_string_char c;
      string lexbuf }

如果您想了解更多信息，可以在此处找到完整的 OCaml 词法分析器源：lexer.mll。

于 2015-10-25T17:12:51.967 回答