python - python模态逻辑K求解器

Answer 1

这是一个非常有趣的项目:)。我自己现在正在写关于模态逻辑的论文。

我首先建议您使用 InToHyLo 输入格式，这在现有求解器中是相当标准的。

InToHyLo 格式如下所示：

  file ::= ['begin'] dml ['end']

  fml ::= '(' fml ')'                        (* parentheses *)
        | '1' | 'true' | 'True' | 'TRUE'     (* truth *)
        | '0' | 'false' | 'False' | 'FALSE'  (* falsehood *)
        | '~' fml | '-' fml                  (* negation *)
        | '<>' fml | '<' id '>' fml          (* diamonds *)
        | '[]' fml | '[' id ']' fml          (* boxes *)
        | fml '&' fml                        (* conjunction *)
        | fml '|' fml                        (* disjunction *)
        | fml '->' fml                       (* implication *)
        | fml '<->' fml                      (* equivalence *)
        | id                                 (* prop. var. *)

   where identifiers (id) are arbitrary nonempty alphanumeric sequences: (['A'-'Z' 'a'-'z' '0'-'9']+)

为了简化公式的解析并专注于真正的问题：解决实例。我建议您使用现有的解析器，例如flex/bison.

通过在 Internet 上查找您的问题，（我远不是 Python 专家）看起来库“ http://pyparsing.wikispaces.com ”是解析的参考。

之后，只需按如下方式使用 Bison，您的文件就会被完全解析。

这是我的 Bison 文件（用于在求解器 C++ 中使用 Flex/Bison）：

/*
 *
 *  Compile with bison.
 */

/*** Code inserted at the begin of the file. ***/
%{   
  #include <stdlib.h>
  #include <list>
  #include "Formula.h"

  // yylex exists
  extern int yylex();
  extern char yytext[];

  void yyerror(char *msg);
%}


/*** Bison declarations ***/
%union
{
   bool         bval;
   operator_t  opval;
   char        *sval;
   TermPtr     *term;      
}

%token LROUND RROUND 

%left IFF
%left IMP
%left OR
%left AND
%right DIAMOND 
%right BOX 
%right NOT 

%token VALUE
%token IDENTIFIER

%type<bval> VALUE
%type<sval> IDENTIFIER 

%type<term> Formula BooleanValue BooleanFormula ModalFormula PropositionalVariable UnaryFormula
%type<opval> BinaryBoolOperator UnaryBoolOperator ModalOperator

%start Start

%%

Start:  
| Formula  { (Formula::getFormula()).setRoot(*$1); }
;

Formula:   BooleanFormula               { $$ = $1; }
         | ModalFormula                 { $$ = $1; }
         | UnaryFormula                 { $$ = $1; }
         | LROUND Formula RROUND        { $$ = $2; }
;

BooleanValue:   VALUE { $$ = new TermPtr( (Term*) new BooleanValue($1) ); }
;

PropositionalVariable:   IDENTIFIER { $$ = new TermPtr( (Term*) new PropositionalVar($1) ); }
;

BooleanFormula:   Formula BinaryBoolOperator Formula { 

                      $$ = new TermPtr( (Term*) new BooleanOp(*$1, *$3, $2) );  /* can be (A OR B) or (A AND B) */
                      delete($3); 
                      delete($1); 
                  }

|                 Formula IMP Formula {

                      ($1)->Negate();
                      $$ = new TermPtr( (Term*) new BooleanOp(*$1, *$3, O_OR) ); /* A -> B can be written : (¬A v B) */
                      delete($3); 
                      delete($1);
                  }

|                 PropositionalVariable IFF PropositionalVariable {

                      PropositionalVar *Copy1 = new PropositionalVar( *((PropositionalVar*)$1->getPtr()) );
                      PropositionalVar *Copy3 = new PropositionalVar( *((PropositionalVar*)$3->getPtr()) );

                      TermPtr Negated1( (Term*)Copy1, $1->isNegated() ); 
                      TermPtr Negated3( (Term*)Copy3, $3->isNegated() );

                      Negated1.Negate(); 
                      Negated3.Negate();

                      TermPtr Or1( (Term*) new BooleanOp(Negated1, *$3, O_OR) ); /* Or1 = (¬A v B) */
                      TermPtr Or2( (Term*) new BooleanOp(Negated3, *$1, O_OR) ); /* Or2 = (¬B v A) */

                      $$ = new TermPtr( (Term*) new BooleanOp(Or1, Or2, O_AND) ); /* We add : (Or1 AND OrB) */

                      delete($3); 
                      delete($1);
                  }                           
;

ModalFormula:   ModalOperator LROUND Formula RROUND  {

                  $$ = new TermPtr( (Term*) new ModalOp(*$3, $1) );
                  delete($3);
                }
|
                ModalOperator ModalFormula  {

                  $$ = new TermPtr( (Term*) new ModalOp(*$2, $1) );
                  delete($2);
                }        
|
                ModalOperator UnaryFormula  {

                  $$ = new TermPtr( (Term*) new ModalOp(*$2, $1) );
                  delete($2);
                }   
;

UnaryFormula:   BooleanValue                 { $$ = $1; }

|               PropositionalVariable        { $$ = $1; }

|
                UnaryBoolOperator UnaryFormula {

                  if ($1 == O_NOT) {
                    ($2)->Negate(); 
                  }                 

                  $$ = $2; 
                }
|
                UnaryBoolOperator ModalFormula {

                  if ($1 == O_NOT) {
                    ($2)->Negate(); 
                  }                 

                  $$ = $2; 
                }                
|
                UnaryBoolOperator LROUND Formula RROUND {

                  if ($1 == O_NOT) {
                    ($3)->Negate(); 
                  }                 

                  $$ = $3; 
                }
;


ModalOperator:   BOX          { $$ = O_BOX; }
|                DIAMOND      { $$ = O_DIAMOND; }
;

BinaryBoolOperator:   AND     { $$ = O_AND; }
|                     OR      { $$ = O_OR; }
;

UnaryBoolOperator:   NOT      { $$ = O_NOT; }
;


/*** Code inserted at the and of the file ***/
%%

void yyerror(char *msg)
{
  printf("PARSER: %s", msg);
  if (yytext[0] != 0)
    printf(" near token '%s'\n", yytext);
  else 
    printf("\n");
  exit(-1);   
}

通过调整它，您将能够完全递归地解析模态逻辑公式:)。

如果以后，您想向现有的画面求解器（例如斯巴达克斯）挑战您的求解器。不要忘记，这些求解器几乎一直都在回答最大开放的 Tableau，因此如果您想找到解决方案的 Kripke 模型，它们肯定会比您更快；）

我希望我能帮助你解决你的问题，我想少一些理论，但不幸的是我没有为此掌握python：/。

祝您与您的求解器取得最好的成绩；

此致。

---

如果您接受我使用 InToHyLo 的提议，我最近在 Kripke 模型的模态逻辑 K 上工作。您可以在此处找到：http ://www.cril.univ-artois.fr/~montmirail/mdk-验证者/

它最近在 PAAR'2016 上发表：

关于检查模态逻辑 K 的 Kripke 模型，Jean-Marie Lagniez、Daniel Le Berre、Tiago de Lima 和 Valentin Montmirail，第五届自动推理实用方面研讨会论文集（PAAR 2016）

Answer 2

这个问题已经对我最初的问题有一个选定的答案。如果有人对不同模型逻辑的完整实现感兴趣，请在此处阅读我的报告。它包含很多细节，所以你不会迷路。

解析器本身 (Python) 的实现可以在我的github repo中找到。代码的文档不是最好的，但如果你理解了这个理论，你应该会发现它很容易，我希望 :)。