4

我正在学习F#，现在正在阅读有关与 SQL 类型提供程序一起使用的计算表达式和查询表达式的信息。我正在做一些简单的任务，并且在某些时候需要连接（联合）2个查询，我的第一个想法是，在阅读了yield序列和列表之后，在这样的查询表达式中做同样的事情：

query {
    yield! for a in db.As select { // projection }
    yield! for b in db.Bs select { // projection }
}

这是无效的代码，然后我的第二种方法是使用以下方法“连接”它们：

seq {
    yield! query {...}
    yield! query {...}
}

或者像这样使用 Linq 的Concat函数(query {...}).Concat(query {...})：如何做到这一点来自这个问题的答案

不过，上述两种方法都有一个区别，使用seq将运行 2 个 SQL 查询，并且Concat只运行一个可以理解的查询。

那么我的问题是：为什么不yield支持查询表达式？

编辑：

经过进一步调查，我找到了MSDN 文档，我看到了实现的YieldandYieldFrom方法，但没有看到CombineandDelay方法，这让我现在更加困惑

4

2 回答 2

3

yield!在查询中得到一定程度的支持，并且可以在select通常情况下使用：

query { 
    for x in [5;2;0].AsQueryable() do 
    where (x > 1)
    sortBy x
    yield! [x; x-1] 
 } |> Seq.toList // [2;1;5;4]

但是，一般来说，您不能随意散布查询和序列操作，因为很难定义它们应该如何组合：

query {
    for x in [1;2;3] do
    where (x > 1)
    while true do // error: can't use while (what would it mean?)
    sortBy x 
}

同样地：

query {
    for x in [1;2;3] do
    where (x > 1)
    sortBy x 
    yield! ['a';'b';'c']
    yield! ['x';'y';'z'] // error
}

这有点模棱两可，因为不清楚第二个yield!是在for循环内还是在之后附加一组元素。

因此，最好将查询视为查询，将序列视为序列，即使这两种计算表达式都支持某些相同的操作。

通常，查询自定义运算符按元素工作，因此表达联合或连接之类的东西很尴尬，因为它们处理的是整个集合而不是单个元素。但是，如果您愿意，您可以创建一个查询构建器，添加一个concat采用序列的自定义运算符，尽管它可能感觉有点不对称：

open System.Linq

type QB() =
    member inline x.Yield v = (Seq.singleton v).AsQueryable()
    member inline x.YieldFrom q = q
    [<CustomOperation("where", MaintainsVariableSpace=true)>]
    member x.Where(q:IQueryable<_>, [<ProjectionParameter>]c:Expressions.Expression<System.Func<_,_>>) = q.Where(c)
    [<CustomOperation("sortBy", MaintainsVariableSpace=true)>]
    member x.SortBy(q:IQueryable<_>, [<ProjectionParameter>]c:Expressions.Expression<System.Func<_,_>>) = q.OrderBy(c)
    [<CustomOperation("select")>]
    member x.Select(q:IQueryable<_>, [<ProjectionParameter>]c:Expressions.Expression<System.Func<_,_>>) = q.Select(c)
    [<CustomOperation("concat")>]
    member x.Concat(q:IQueryable<_>, q') = q.Concat(q')
    member x.For(q:IQueryable<'t>, c:'t->IQueryable<'u>) = q.SelectMany(fun t -> c t :> seq<_>) // TODO: implement something more reasonable here

let qb = QB()

qb {
    for x in ([5;2;0].AsQueryable()) do
    where (x > 1)
    sortBy x
    select x
    concat ([7;8;9].AsQueryable())
} |> Seq.toList
于 2015-10-20T16:30:29.147 回答
1

这是 F# 中查询表达式的绝佳参考：https ://msdn.microsoft.com/en-us/library/hh225374.aspx

特别是，我认为该页面中的以下示例可以满足您的要求：

let query1 = query {
        for n in db.Student do
        select (n.Name, n.Age)
    }

let query2 = query {
        for n in db.LastStudent do
        select (n.Name, n.Age)
        }

query2.Union (query1)
于 2015-10-20T01:10:01.363 回答