batch-file - 如何删除文件的最后一个字符

Question

我使用这个批处理文件来创建文件列表

@echo off
(for /f "delims=" %%a in ('dir/b/a-d *.tex') do   echo %%a,)>liste.dat

结果是这样的

file1.tex,
file2.tex,
file3.tex,
...
lastfile.tex,

如何删除最后一个逗号？

Answer 1

@echo off
SETLOCAL EnableDelayedExpansion
SET "in="
(
for %%a in (*.tex) do (
    IF "!in!"=="" (
        set in=%%a
    ) ELSE (
        echo !in!,
        set in=%%a
    )
)
echo !in!
)>liste.dat

Answer 2

@echo off
setlocal EnableDelayedExpansion

set "comma="
< NUL (
for %%a in (*.tex) do (
   set /P "=!comma!%%a"
   set comma=,^
%Empty line%
)
echo/
) > liste.dat

编辑：回复评论

行动！当我开发这段代码时，我只是在屏幕上显示了输出，它看起来是正确的：

C:\> test.bat
One.tex,
Three.tex,
Two.tex

即使将输出发送到文件并且文件显示在屏幕中，输出看起来也是正确的：

C:\> test.bat > output.txt

C:\> type output.txt
One.tex,
Three.tex,
Two.tex

但是，在每个逗号之后插入的字符只是一个 LF，因此如果使用记事本打开此文件，则 LF不会转换为“行尾”；只是 cmd.exe屏幕输出将 LF 转换为 CR+LF 对（“熟输出”而不是“原始输出”）。

修复这个细节的方法是在每个逗号后插入一个完整的 CR+LF 对：

@echo off
setlocal EnableDelayedExpansion

for /F %%a in ('copy /Z "%~F0" NUL') do set "CR=%%a"

set "comma="
< NUL (
for %%a in (*.tex) do (
   set /P "=!comma!%%a"
   set comma=,!CR!^
%Empty line%
)
echo/
) > liste.dat

Answer 3

问题是你不知道会有多少行/文件。因此，您必须按照编写代码的方式使用两个循环。一个用于计算行数，一个用于执行操作。对第一行而不是最后一行进行不同的处理要容易得多。那么这个怎么样：

@echo off
SETLOCAL EnableDelayedExpansion
SET /a i=0
(for /f "delims=" %%a in ('dir /b/a-d *.tex') do (
    IF !i!==1 (
        echo ,%%a
    ) ELSE (
        ECHO %%a
        SET /a i=1
    )
)
)>liste.txt

这将生成如下内容：

file1.tex
,file2.tex
,file3.tex
...
,lastfile.tex

这似乎等同于您想要的输出。如果您真的想,在行的末尾而不是在下一行的开头，请告诉我，我会更新代码，但它会非常难看。