4

假设我有一个元素<x>x</x>和一些空元素(<a/>, <b/>, <c/>)，我想一次将第一个元素包裹在第二个元素中，结果是<c><b><a><x>x</x></a></b></c>. 当我不知道空元素的数量时，我该如何处理？

我可以

xquery version "3.0";

declare function local:wrap-up($inner-element as element(), $outer-elements as element()+) as element()+ {
    if (count($outer-elements) eq 3)
    then element{node-name($outer-elements[3])}{element{node-name($outer-elements[2])}{element{node-name($outer-elements[1])}{$inner-element}}}
    else 
        if (count($outer-elements) eq 2)
        then element{node-name($outer-elements[2])}{element{node-name($outer-elements[1])}{$inner-element}}
        else
            if (count($outer-elements) eq 1)
            then element{node-name($outer-elements[1])}{$inner-element}
            else ($outer-elements, $inner-element)
};

let $inner-element := <x>x</x>
let $outer-elements := (<a/>, <b/>, <c/>)

return 
    local:wrap-up($inner-element, $outer-elements)

但是有没有办法通过递归来做到这一点，而不是下降和解析，而是上升和构造？

4

1 回答 1

5

在函数式编程中，您通常尝试使用列表的第一个元素和尾部，因此规范的解决方案是在嵌套元素之前反转输入：

declare function local:recursive-wrap-up($elements as element()+) as element() {
  let $head := head($elements)
  let $tail := tail($elements)
  return
    element { name($head) } { (
      $head/@*,
      $head/node(),
      if ($tail)
      then local:recursive-wrap-up($tail)
      else ()
    ) }
};

let $inner-element := <x>x</x>
let $outer-elements := (<a/>, <b/>, <c/>)

return (
    local:wrap-up($inner-element, $outer-elements),
    local:recursive-wrap-up(reverse(($inner-element, $outer-elements)))
)

是否reverse(...)真的需要反转输出取决于您的 XQuery 引擎。最后，逆向不会增加计算复杂度，而且可能不仅会导致代码更清晰，而且执行速度会更快！

类似的方法可以通过颠倒所有内容来实现，但是没有函数可以获取最后一个元素和之前的所有内容，并且可能会在使用谓词last()和时降低性能position() < last()。您可以使用 XQuery 数组，但必须在每个递归函数调用中传递计数器。

最终哪种解决方案最快将需要使用特定的 XQuery 引擎和代码进行基准测试。

于 2015-10-17T15:36:47.210 回答