1

有一些我正在调用从 FTP 下载文件的主要表单。提出此操作时，我希望ShowDialog同时显示新表单和进度条，然后显示进度并关闭新表单并返回主表单。但是，我的代码正在工作，当它开始处理时，我的主表单冻结，然后出现新表单然后关闭。我想更正的是在执行流程后立即显示这个新表格。你能看看并告诉我有什么问题吗？

这不是我的主要形式，下载过程称为：

Dim pro As New FrmProgressBarWinscp(WinScp, myremotePicturePath, ladujZdjeciaPath, True)

FrmProgressBarWinscp如下：

Public Class FrmProgressBarWinscp

    Property _winScp As WinScpOperation
    Property _remotePicture As String
    Property _ladujZdjecia As String
    Property _removesource As String

    Public Sub New()
        InitializeComponent()
    End Sub

    Sub New(winscp As WinScpOperation, remotePicture As String, ladujzdjecia As String, removesource As Boolean)
        ' This call is required by the designer.
        InitializeComponent()
        ' Add any initialization after the InitializeComponent() call.
        _winScp = winscp
        _remotePicture = remotePicture
        _ladujZdjecia = ladujzdjecia
        _removesource = removesource
        ShowDialog()
    End Sub

    Sub Run()

        Try
            Cursor = Cursors.WaitCursor
            _winScp.GetFile(_remotePicture, _ladujZdjecia, _removesource)
            ProgressBar1.Minimum = 0
            ProgressBar1.Maximum = 1
            ProgressBar1.Value = 0
            Do
                ProgressBar1.Value = WinScpOperation._lastProgress
                ProgressBar1.Refresh()
            Loop Until ProgressBar1.Value = 1
            Cursor = Cursors.Default
            'Close()

        Catch ex As Exception

        Finally
            If _winScp IsNot Nothing Then
                _winScp.SessionDispose()
            End If

            System.Threading.Thread.Sleep(10000)
            Close()
        End Try

    End Sub

    Private Sub FrmProgressBarWinscp_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Run()
    End Sub
End Class

Winscp我自己的类和使用的方法：

...
Function GetFile(source As String, destination As String, Optional removeSource As Boolean = False)
    Dim result As Boolean = True
    Try

        session.GetFiles(source, destination, removeSource).Check()

    Catch ex As Exception
        result = False
    End Try
    Return result
End Function

Private Shared Sub SessionFileTransferProgress(sender As Object, e As FileTransferProgressEventArgs)
    'Print transfer progress
    _lastProgress = e.FileProgress

End Sub

Public Shared _lastProgress As Integer

...

进一步讨论第 3 条：

Main form:
 Dim tsk As Task(Of Boolean) = Task.Factory.StartNew(Of Boolean)(Function()
                                                                                                Return WinScp.GetFile(myremotePicturePath, ladujZdjeciaPath, True)

                                                                                            End Function)


                            Dim forma As New FrmProgressBar
                            forma.ShowDialog()

进度条形式：

Public Class FrmProgressBar

    Public Sub New()
        InitializeComponent()
    End Sub
    Sub Run()
        Try
            Do
                ProgressBar1.Value = WinScpOperation._lastProgress
                ProgressBar1.Refresh()
            Loop Until ProgressBar1.Value = 1
            Cursor = Cursors.Default

        Catch ex As Exception
        Finally
            MsgBox("before sleep")
            System.Threading.Thread.Sleep(10000)
            MsgBox("after sleep sleep")
            Close()
        End Try
    End Sub

    Private Sub FrmProgressBarWinscp_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Run()
    End Sub
End Class

点号。4：

  Dim tsk As Task(Of Boolean) = Task.Factory.StartNew(Of Boolean)(Function()
                                                                                                Return WinScp.GetFile(myremotePicturePath, ladujZdjeciaPath, True)

                                                                                            End Function)


                            Dim pic As New Waiting
                            pic.ShowDialog()

                            Task.WaitAll(tsk)
                            pic.Close()

第 5 点：

 Dim pic As New Waiting
                            pic.ShowDialog()
                            Dim tsk As Task = Task.Factory.StartNew(Sub() WinScp.GetFile(myremotePicturePath, ladujZdjeciaPath, pic, True))




                            Task.WaitAll(tsk)
                            'pic.Close()

在其他一些类中（在这个方法被放在不同的类中之前可能没有提到 - 我的自定义类）

Public Function GetFile(source As String, destination As String, formclose As InvokeCloseForm, Optional removeSource As Boolean = False) As Boolean
        Dim result As Boolean = True
        Try
            session.GetFiles(source, destination, removeSource).Check()
        Catch ex As Exception
            result = False
        End Try
        formclose.RUn()
        Return result
    End Function

界面：

Public Interface InvokeCloseForm
    Sub RUn()
End Interface

等候表格：

Public Class Waiting
    Implements InvokeCloseForm

    Public Sub RUn() Implements InvokeCloseForm.RUn
        Me.Close()
    End Sub
End Class
4

1 回答 1

1

阻塞中的Session.GetFiles方法。

这意味着它仅在传输完成后返回。

解决方案是：

  • Session.GetFiles在单独的线程中运行 WinSCP 传输 ( )，而不是阻塞 GUI 线程。

    为此，请参阅WinForm Application UI Hangs during Long-Running Operation

  • 处理Session.FileTransferProgress事件。

    虽然请注意，事件处理程序将在后台线程上调用，因此您不能直接从处理程序更新进度条。您必须使用Control.Invoke来确保在 GUI 线程上更新进度条。

    为此，请参阅如何从另一个线程更新 GUI？

  • 下面是一个简单的实现。

    有关代码的更多版本，请参阅 WinSCP 文章在 WinForms ProgressBar 上显示 FTP/SFTP 传输进度。

    Public Class ProgressDialog1

    Private Sub ProgressDialog1_Load(
            sender As Object, e As EventArgs) Handles MyBase.Load
        ' Run download on a separate thread
        ThreadPool.QueueUserWorkItem(New WaitCallback(AddressOf Download))
    End Sub

    Private Sub Download(stateInfo As Object)
        ' Setup session options
        Dim mySessionOptions As New SessionOptions
        With mySessionOptions
            ... 
        End With

        Using mySession As Session = New Session
            AddHandler mySession.FileTransferProgress,
                AddressOf SessionFileTransferProgress

            ' Connect
            mySession.Open(mySessionOptions)

            mySession.GetFiles(<Source>, <Destination>).Check()
        End Using

        ' Close form (invoked on GUI thread)
        Invoke(New Action(Sub() Close()))
    End Sub

    Private Sub SessionFileTransferProgress(
            sender As Object, e As FileTransferProgressEventArgs)
        ' Update progress bar (on GUI thread)
        ProgressBar1.Invoke(
            New Action(Of Double)(AddressOf UpdateProgress), e.OverallProgress)
    End Sub

    Private Sub UpdateProgress(progress As Double)
        ProgressBar1.Value = progress * 100
    End Sub
End Class

  • 如果您想阻止用户执行某些操作，您可能希望在操作期间禁用进度表单（或其部分）。

    使用.Enabled窗体或控件的属性。

Application.DoEvents更简单但很麻烦且通常不推荐的解决方案是从现有SessionFileTransferProgress处理程序中调用该方法。

当然，您还必须从 更新进度条SessionFileTransferProgress。

Private Shared Sub SessionFileTransferProgress(
        sender As Object, e As FileTransferProgressEventArgs)
    'Print transfer progress
    ProgressBar1.Value = e.FileProgress
    Application.DoEvents
End Sub

并且进度条的.Minimumand.Maximum必须设置在Session.GetFiles.

但不要那样做！这是错误的做法。

而且，您仍然需要以与上述正确解决方案相同的方式禁用表单/控件。

于 2015-10-08T10:57:06.093 回答