3

我在存储为字符串的对象中有一个名为 HistoryText 的属性。我想在网格中显示所有行。我应该能够删除和编辑网格中的行。格式为：

16.5.2003-$-12:09-$-anna-$-Organization created
2.6.2005-$-13:03-$-jimmy-$-Organization edited
19.12.2005-$-13:33-$-madeleine-$-Organization edited

所以每一行都有 4 个字段，日期、时间、用户和消息，分隔符字符串为“-$-”。作为分隔符一个字符串而不是一个字符，它不能被分配给 stringlists delimiter 属性。

我有一个例程将字符串提取到 Stringlist：

procedure ParseDelimited(const aStringList: TStringList; const aOrgList, aDelimiter: string);
var
   vDelimiterPos : integer;
   vPartialStr : string;
   vRemaingTxt : string;
   vDelimiterLength : integer;
begin
   vDelimiterLength := Length(aDelimiter);

   if (AnsiRightStr(aOrgList, Length(aDelimiter)) = aDelimiter) then
     vRemaingTxt := aOrgList
   else
     vRemaingTxt := aOrgList + aDelimiter;

   aStringList.BeginUpdate;
   aStringList.Clear;
   try
     while Length(vRemaingTxt) > 0 do
     begin
       vDelimiterPos := Pos(aDelimiter, vRemaingTxt);
       vPartialStr := Copy(vRemaingTxt,0,vDelimiterPos-1);
       aStringList.Add(vPartialStr);
       vRemaingTxt := Copy(vRemaingTxt,vDelimiterPos+vDelimiterLength,MaxInt);
     end;
   finally
     aStringList.EndUpdate;
   end;
end;

它似乎工作正常。我的问题是将 StringList 中的更改同步回原始 String 属性？这个分隔符有很多历史数据，所以我不认为将其更改为 TChar 是一个现实的选择。

更新： 澄清。我想我可以设法使用上面的方法将 String 转换为 StringList 。然后在网格中显示它应该不会那么难。当我想将 TStringList 转换回原始的 String 属性时，问题就出现了，以 '-$-' 作为分隔符。例如，我不能做 HistoryText := myStringList.Delimitedtext。

第二次更新： 我已经解决了。你们都得到了 +1 的快速答案，并且真的很想提供帮助。总结一下我是怎么做到的。

从历史文本中读取：

MyStringList.Text := Historytext;

现在每一行都有 3 个 '-$-' 分隔符，并且每行像往常一样由换行符分隔。

  • 在循环中解析 Stringlist 并将其显示在网格中。我不再关心 MyStringList 了。
  • 让用户删除和编辑网格中的行。
  • 完成后在网格中按行和列循环并构建一个与原始格式相同的新字符串。
  • 将该字符串分配给 HistoryText。

所以将焦点从 StringList 转移到网格上更容易:)

4

2 回答 2

6

除了 Delimiter（一个字符）和 DelimitedText，您还可以使用 LineBreak（一个字符串）和 Text：

lst := TStringList.Create;
try
  lst.LineBreak := '-$-';
  lst.Text := '16.5.2003-$-12:09-$-anna-$-Organization created';
  Memo1.Lines := lst;  // or whatever you do with it
finally
  lst.Free;
end;

Ans 它甚至可以反过来工作。

于 2010-07-21T10:17:13.273 回答
2

黑暗中的狂野刺（不是很清楚你在问什么）：

处理网格行：

  • 对于每一行：
    • 将空字符串分配给临时字符串 var
    • 对于每一列，将行/列值加上您的分隔符添加到临时字符串 var
    • 从临时字符串 var 中删除最后一个分隔符（如果它非空）
    • 将临时字符串 var 添加到字符串列表
  • 将 stringlist 的 text 属性写回 HistoryText
const
  Delimiter = '-$-';
var
  row: Integer;
  col: Integer;
  SL: TStringList;
  rowString: string;
begin
  SL := TStringList.Create;
  try
    for row := 0 to StringGrid1.RowCount - 1 do begin
      rowString := '';
      for col := 0 to StringGrid1.ColCount - 1 do begin
        rowString := StringGrid1.Cells[col, row] + Delimiter;
      end;
      if rowString <> '' then begin
        rowString := Copy(rowString, 1, Length(rowString) - Length(Delimiter));
      end;
      SL.Add(rowString);
    end;
    HistoryText := SL.Text;
  finally
    SL.Free;
  end;
end;

使用 Uwe 对 TStrings 的 LineBreak 属性的解决方案：

var
  row: Integer;
  col: Integer;
  SLRows: TStringList;
  SLCols: TStringlist;
begin
  SLRows := TStringList.Create;
  try
    SLCols := TStringList.Create;
    try
      SLCols.LineBreak := '-$-';
      for row := 0 to StringGrid1.RowCount - 1 do begin
        SLCols.Clear;
        for col := 0 to StringGrid1.ColCount - 1 do begin
          SLCols.Add(StringGrid1.Cells[col, row]);
        end;
        SLRows.Add(SLCols.Text);
      end;
      HistoryText := SLRows.Text;
    finally
      SLCols.Free;
    end;
  finally
    SLRows.Free;
  end;
end;
于 2010-07-21T10:08:29.127 回答