8

我正在尝试使用GObject Introspection和Moo在 Perl 中创建 Gtk3 应用程序。有一个来自 Gtk 的非 Moo 类Gtk::ApplicationWindow，我通过 Moo 使用extends 'Gtk::ApplicationWindow'. 问题是，当创建该子类的对象时，它仍然是父类的类型 - 即Gtk::ApplicationWindow.

我通过子类化我自己的非 Moo 类来尝试同样的事情，并且从这个子类创建的对象是正确的类型。造成这种差异的原因可能是什么？

use v5.10;
use strict;
use warnings;

# Import the Gtk classes (non-Moo)
use Glib::Object::Introspection;
Glib::Object::Introspection->setup(basename => 'Gtk', version => '3.0', package => 'Gtk');
Glib::Object::Introspection->setup(basename => 'Gio', version => '2.0', package => 'Gio');

#################################################
{
    # A dummy non-Moo class
    package ClassNonMoo;
    sub new { bless {}, shift; }
}

{
    # Moo class extending the dummy class
    package ClassMoo;
    use Moo;

    extends 'ClassNonMoo';

    sub FOREIGNBUILDARGS {
        my ($class, %args) = @_;
        return ($args{app});
    }
}
#################################################

{
    # Moo class extending Gtk::ApplicationWindow
    package ClassMooGtkAppWin;
    use Moo;

    extends 'Gtk::ApplicationWindow';

    sub FOREIGNBUILDARGS {
        my ($class, %args) = @_;
        return ($args{app});
    }
}

#################################################

# Create objects of ClassMoo and ClassMooGtkAppWin
sub create_objects {
    my ($app) = @_;

    my $o1 = ClassMoo->new( app => $app );
    my $o2 = ClassMooGtkAppWin->new( app => $app );

    say "o1 = $o1\no2 = $o2";
    # Output:
    # o1 = ClassMoo=HASH(0x2f7bc50)
    # o2 = Gtk::ApplicationWindow=HASH(0x2f7bd40)
    #
    # Shouldn't o2 be of the type ClassMooGtkAppWin ?

    exit(0);
}

# We can create a GtkApplicationWindow only after creating a GtkApplication and
# running it. This code just ensures that create_object() is called once the
# application is 'active'.
my $app = Gtk::Application->new('org.test', 'flags-none');
$app->signal_connect(activate => sub { create_objects($app) });
$app->run();
4

2 回答 2

4

“新”构造函数需要以观察调用者的实际类（与子类化一起使用）的方式编写，但它们也可以硬编码它们创建对象的类。

比较：

package MyClass;

# Considerate of subclassing
sub new {
    my $class = shift;
    return bless {}, $class;
}

# Doesn't give a shit
sub new {
    my $class = shift;
    return bless {};
}

Glib 看起来像是一个围绕 C 库的 XS 模块包装器，它可能对类进行硬编码。

您可能只是尝试将对象重新祝福（在构造的对象上再次调用 bless）到您的实际子类中。不确定这将如何与 Moo 一起使用，但可能在 BUILD 方法中。

您也可以跳过继承而使用委托。创建一个属性来保存原始 Window 对象，然后将所有方法委托给它，子类中您自己的方法除外。

在 Moose（不是 Moo）中，您可以使用正则表达式执行此操作： https ://metacpan.org/pod/Moose#handles-ARRAY-HASH-REGEXP-ROLE-ROLETYPE-DUCKTYPE-CODE

不知道如何用 Moo 很好地做到这一点。

于 2015-09-30T19:33:21.647 回答
2

我找不到 Gtk::ApplicationWindow 来验证，但它可能确实如此

sub new {
   my ($class) = @_;
   return bless({});
}

代替

sub new {
   my ($class) = @_;
   return bless({}, $class);
}
于 2015-09-30T14:50:08.040 回答