10

对于某些编译器，在 C 程序中使用pow和某些其他函数需要链接到m库。但是，一些编译器不需要这样做，并且在链接到m库时会出错。std::thread使用and的 C++ 存在几乎相同的情况pthread，但 CMake 模块FindThreads完全缓解了这种情况 - libm 是否有一些类似的模块？

检测如何使用 CMake 的最佳方法是什么？这是我目前的解决方案，它不太理想，因为 C 编译器不仅仅是 GCC 和 MSVC：

if(NOT MSVC)
    target_link_libraries(my-c-target PUBLIC m)
endif()

这适用于我的目的，但我很确定在某些情况下它会失败并需要手动用户干预，这对于不了解这种默默无闻的人来说并不有趣。理想情况下，我不希望用户必须通过命令行指定他们的编译器是否奇怪；我想在 CMake 中自动检测它，因为这是 CMake 的重点。

4

3 回答 3

9

您应该使用该CHECK_FUNCTION_EXISTS命令检查是否pow可以在没有附加标志的情况下使用。如果此检查失败，您可以将m库添加到CMAKE_REQUIRED_LIBRARIES变量，假设libm缺少链接。但是您需要CHECK_FUNCTION_EXISTS再次确保链接足够。

示例代码：

include(CheckFunctionExists)

if(NOT POW_FUNCTION_EXISTS AND NOT NEED_LINKING_AGAINST_LIBM)
  CHECK_FUNCTION_EXISTS(pow POW_FUNCTION_EXISTS)
  if(NOT POW_FUNCTION_EXISTS)
      unset(POW_FUNCTION_EXISTS CACHE)
      list(APPEND CMAKE_REQUIRED_LIBRARIES m)
      CHECK_FUNCTION_EXISTS(pow POW_FUNCTION_EXISTS)
      if(POW_FUNCTION_EXISTS)
          set(NEED_LINKING_AGAINST_LIBM True CACHE BOOL "" FORCE)
      else()
          message(FATAL_ERROR "Failed making the pow() function available")
      endif()
  endif()
endif()

if (NEED_LINKING_AGAINST_LIBM)
     target_link_libraries(your_target_here m)
endif()
于 2015-09-28T10:29:21.593 回答
4

检查某些代码是否对编译器正确的常用方法是try_compile。

使用_pow.c：

#include <math.h>
int main(void) {return pow(2, 2.5);}

CMakeLists.txt：

...
if(NOT DEFINED POW_LIBS)
    try_compile(pow_use_m # RESULT_VAR
                check_pow # bindir
                use_pow.c # srcfile
                LINK_LIBRARIES m)
    if(pow_use_m)
        set(POW_LIBS m CACHE INTERNAL "Libraries for use pow")
    else()
        set(POW_LIBS "" CACHE INTERNAL "Libraries for use pow")
    endif()
endif()

...
target_link_libraries(my-c-target PUBLIC ${POW_LIBS})

缓存条目包含使用功能POW_LIBS所需的库。pow

于 2015-09-28T10:23:27.643 回答
2

如果我理解正确，libm如果存在链接，则始终首选链接。

因此，CheckLibraryExists有效。

CMakeLists.txt

set(POW_LIBS "")
include(CheckLibraryExists)
check_library_exists(m pow "" LIBM)
if(LIBM)
    list(APPEND POW_LIBS "m")
endif()

...
target_link_libraries(my-c-target PUBLIC ${POW_LIBS})

使用 Linux x86_64、glibc 2.23 cmake 3.13.2 测试

于 2019-02-15T04:02:11.297 回答