7

我有一个问题：我想创建一个可以容纳 1M 同时打开的 tcp 连接的 Erlang 服务器。我调整了我的操作系统（Oracle Linux 7）来提升文件描述符。在服务器上我做 gen_tcp:listen

// point_1
Socket = gen_tcp:accept
spawn(handle(Socket)) // 另一个线程
回到 point_1

如果我按顺序连接没问题，在 100 秒内我连接了 10 万个客户端；但我没有耐心等待更多。

例如，如果我想以一种并发的方式连接它们，那么只有大约 80 个连接来自 100 个。

这就是我运行一切的方式：

erlc *.erl
erl +Q 134217727 +P 1000000 -env ERL_MAX_PORTS 40960000 -env ERTS_MAX_PORTS 40960000

// 启动一台服务器，监听 9999 端口

ex:start(1, 9999)

// 100 个客户端尝试连接端口 9999

ex:connect_clients(100, 9999)

让我给你看一些代码：

start(Num,LPort) ->
  case gen_tcp:listen(LPort,[{active, false},{packet,2}]) of
    {ok, ListenSock} ->
      start_servers(Num,ListenSock),
      {ok, Port} = inet:port(ListenSock),
      Port;
    {error,Reason} ->
      {error,Reason}
  end.

start_servers(0,_) ->
  ok;
start_servers(Num,LS) ->
  spawn(?MODULE,server,[LS,0]),
  start_servers(Num-1,LS).

server(LS, Nr) ->
  io:format("before accept ~w~n",[Nr]),
  case gen_tcp:accept(LS) of
    {ok,S} ->
      io:format("after accept ~w~n",[Nr]),
      spawn(ex,loop,[S]),
      server(LS, Nr+1);
    Other ->
      io:format("accept returned ~w - goodbye!~n",[Other]),
      ok
  end.

loop(S) ->
  inet:setopts(S,[{active,once}]),
  receive
    {tcp,S, _Data} ->
      Answer = 1, 
      gen_tcp:send(S,Answer),
      loop(S);
    {tcp_closed,S} ->
      io:format("Socket ~w closed [~w]~n",[S,self()]),
      ok
  end.

client(PortNo) ->
  {ok,Sock} = gen_tcp:connect("localhost", PortNo,
    []).

connect_clients(Number, Port) ->
  spawn(ex, client, [Port]),
  case Number of
    0 -> ok;
    _ -> connect_clients(Number-1, Port)
  end.
4

1 回答 1

7

我在这里至少看到两个问题：

  • 你需要提高你的收听积压；它默认为 5。您可以通过设置{backlog, N}监听选项来提高它，例如{backlog, 1024}.

  • 您的server/2函数有问题，因为它接受连接，然后生成一个新进程来运行loop/1，但它不会使该新进程成为已接受套接字的控制进程。该loop/1函数尝试{active,once}在套接字上设置模式以尝试接收传入消息，但由于它没有在控制进程中运行，所以它不会工作。inet_setopts/2（您应该通过说ok = inet:setopts(S,[{active,once}]),那里来验证返回值。）

与其生成循环，不如生成一个新的接受器，如下所示：

server(LS, Nr) ->
  io:format("before accept ~w~n",[Nr]),
  case gen_tcp:accept(LS) of
    {ok,S} ->
      io:format("after accept ~w~n",[Nr]),
      spawn(ex,server,[LS,Nr+1]),
      loop(S);
    Other ->
      io:format("accept returned ~w - goodbye!~n",[Other]),
      ok
  end.

使用这种方法，接受套接字的进程运行loop/1，因此无需更改套接字的控制进程。

于 2015-09-22T08:13:05.643 回答