10

我正在尝试采用例如ExceptT a (StateT A M)某些具体类型A和 monad M，并将它们包装到我的新自定义 monad 中。

首先，我发现它StateT A M经常出现在其他上下文中，因此我决定最好将它单独包装在 monad 中M1，然后包装ExceptT a M1到M2.

所需的属性是创建M1和M2实例MonadState和类M（假设它被称为MyMonadClass）。也M2应该是MonadError.

首先，我从简单的类型同义词开始：

type MyState    = StateT A M
type MyBranch a = ExceptT a MyState

然后我想我会先画出实例声明（不实现实例），这就是我第一次陷入困境的地方。instance MonadState A (MyState)似乎不是正确的语法。我想我必须创建newtype MyState' a = StateT a M然后type MyState = MyState A（让我们不要在不必要的地方使用语言扩展）。

但是，一旦我开始将同义词转换为newtype声明，我就开始失去与StateT A MandExceptT ...类型的联系。

newtype MyState' s a = MyState' { runMyState :: s -> (s, a) }
type MyState = MyState' A
newtype MyBranch e a = MyBranch { runMyBranch :: MyState (Either e a) }

现在已经实现的转换器消失了，我想我正在尝试做一些没有多大意义的事情。所以我的问题是：如何将这种行为正确地包装到新的复合 monad 中，以便可以访问下面的层，从而避免不必要的提升，并使事情保持清晰和井井有条。

4

1 回答 1

12

正常模式是为您的完整变压器堆栈定义一个新类型。

data A = A
data E = E

newtype MyBranchT m a = MyBranchT { getMyBranchT :: ExceptT E (StateT A m) a }

如果堆栈中有任何部分可以自行添加有意义的新功能，那么您还需要为这些部分定义新类型。

然后，您可以使用GeneralizedNewtypeDeriving获取所有各种 monad 类的实例。

{-# LANGUAGE GeneralizedNewtypeDeriving #-}

-- base
import Control.Applicative
import Control.Monad

-- transformers
import Control.Monad.IO.Class
import Control.Monad.Trans.Class
import Control.Monad.Trans.Except
import Control.Monad.Trans.State.Lazy

-- mtl classes
import Control.Monad.Cont.Class
import Control.Monad.Error.Class
import Control.Monad.Reader.Class
import Control.Monad.State.Class
import Control.Monad.Writer.Class

data A = A
data E = E

newtype MyBranchT m a = MyBranchT { getMyBranchT :: ExceptT E (StateT A m) a }
    deriving (Functor, Applicative, Monad, MonadIO,     -- classes from base and transformers
              {- Alternative, MonadPlus, -}             -- if E is a monoid
              MonadState A, MonadError E,               -- classes from mtl that MyBranchT provides
              MonadCont, MonadReader r, MonadWriter w)  -- classes from mtl that might be available from m

您必须MonadTrans手动编写实例。lift对于堆栈中的每个变压器，总是只有lift一次。

instance MonadTrans MyBranchT where
    lift = MyBranchT . lift . lift

如果堆栈中的任何部分自己添加了有意义的新功能X，您还需要为这些功能定义一个新类，如果可能的话，为每个 monad 转换器（, ,等）MonadX编写实例，并为您的变压器堆栈 ( )。MonadXStateTExceptTContTMonadXMyBranchT

您通常还会为MyBranchT Identity和函数创建一个类型同义词runMyBranchT和runMyBranch

import Data.Functor.Identity

type MyBranch a = MyBranchT Identity a

runMyBranchT :: MyBranchT m a -> A -> m (Either E a, A)
runMyBranchT mb s = runStateT (runExceptT (getMyBranchT mb)) s

runMyBranch :: MyBranch a -> A -> (Either E a, A)
runMyBranch mb s = runIdentity $ runMyBranchT mb s
于 2015-09-14T19:42:53.900 回答