2

假设我想以简单的匹配方式找到区分两个类的一组特征/属性，我可以在 prolog 中使用 clpfd 来做到这一点吗？

c_s_mining(Features,Value):-
 Features = [F1,F2,F3,F4],
 Features ins 0..1,
 ExampleA = [A1,A2,A3,A4],
 ExampleB =[B1,B2,B3,B4],
 ExampleC =[C1,C2,C3,C4],
 A1 #=0, A2#=1,A3#=0,A4#=1,
 B1 #=0, B2#=1,B3#=0,B4#=1,
 C1 #=1, C2#=0,C3#=0,C4#=1,

 ExampleD =[D1,D2,D3,D4],
 ExampleE =[E1,E2,E3,E4],
 ExampleQ =[Q1,Q2,Q3,Q4],
 D1#=1,D2#=0,D3#=1,D4#=0,
 E1#=1,E2#=0,E3#=1,E4#=0,
 Q1#=0,Q2#=1,Q3#=1,Q4#=0,

 Positives =[ExampleA,ExampleB,ExampleC],
 Negatives = [ExampleD,ExampleE,ExampleQ],
 TP in 0..sup,
 FP in 0..sup,
 covers(Features,Positives,TP),
 covers(Features,Negatives,FP),
 Value  in inf..sup,
 Value #= TP-FP.


covers(Features,Examples,Number_covered):-
   findall(*,(member(E,Examples),E=Features),Covers), length(Covers,Number_covered).

每个示例由四个二元特征描述，并且有三个正示例（A，B，C）和三个负示例（D，E，Q）。

如果它们匹配，则一组选定的特征将覆盖一个示例。因此，例如，如果Features与 统一[0,1,0,1]，那么这将匹配两个正数和 0 个负数。

我设置Value为等于TP（真阳性）- TN（真阴性）。我想最大化价值并找到相应的特征集。

我查询?-c_s_mining(Features,Value),labelling([max(Value)],[Value]). 我期望的答案是：Features =[0,1,0,1], Value =2但我得到Features =[_G1,_G2,_G3,G4],Value =0, G1 in 0..1, G2 in 0..1, G3 in 0..1, G4 in 0..1.

4

1 回答 1

3

CLP(FD) 约束的具体化

要推断什么匹配什么不匹配，请使用约束具体化：它允许您将约束的真值反映到表示布尔值的 CLP(FD) 变量中。

您可以使用这些值执行算术以表示匹配示例的数量等。

例如，在您的情况下，您可以编写：

:- use_module(library(clpfd)).

c_s_mining(Features, Value) :-
    ExampleA = [0,1,0,1],
    ExampleB = [0,1,0,1],
    ExampleC = [1,0,0,1],

    ExampleD = [1,0,1,0],
    ExampleE = [1,0,1,0],
    ExampleQ = [0,1,1,0],

    same_length(Features, ExampleA),
    Features ins 0..1,
    Positives = [ExampleA,ExampleB,ExampleC],
    Negatives = [ExampleD,ExampleE,ExampleQ],
    covers_number(Features, Positives, TP),
    covers_number(Features, Negatives, FP),
    Value #= TP-FP.


covers_number(Features, Examples, Number):-
    maplist(covers_(Features), Examples, Numbers),
    sum(Numbers, #=, Number).

covers_([F1,F2,F3,F4], [E1,E2,E3,E4], Covered) :-
    Covered #<==> (F1#=E1 #/\ F2#=E2 #/\ F3#=E3 #/\ F4#=E4).

然后使用 的优化选项labeling/2首先获得最大值：

?- c_s_mining(Fs, Value), labeling([max(Value)], Fs)。
Fs = [0, 1, 0, 1],
值 = 2；
Fs = [1, 0, 0, 1],
值 = 1；
Fs = [0, 0, 0, 0],
值 = 0 ;
等等

另请注意，我已经删除了一些多余的约束，例如Value in inf..sup，因为约束求解器可以自己解决它们。

CLP(B)：布尔约束的声明式替代方案

对于这种布尔模式的情况，还可以查看 CLP( B )：基于布尔变量的约束逻辑编程，例如在 SICStus Prolog 和 SWI 中可用。使用 CLP(B) 需要您对搜索进行稍微不同的表述，因为它缺少 CLP(FD) 的强大标签选项。然而，与 CLP(FD) 相比，CLP(B) 是完整的，并且可以更早地检测到不一致以及包含的约束。

在下面的代码中，我使用 CLP(FD) 来指导对最优值的搜索，然后使用 CLP(B) 来说明实际的约束条件。labeling/1（请注意，这是 from library(clpb)，不要与 CLP(FD)'s 混淆）的最终调用labeling/2用于确保所有 CLP(B) 变量的基本值。在它出现的那一点上，它只是某种意义上的形式：由于 CLP(B) 的完整性，我们已经知道在这一点上有一个解决方案。

:- use_module(library(clpb)).
:- use_module(library(clpfd)).

c_s_mining(Features, Value):-
    ExampleA = [0,1,0,1],
    ExampleB = [0,1,0,1],
    ExampleC = [1,0,0,1],

    ExampleD = [1,0,1,0],
    ExampleE = [1,0,1,0],
    ExampleQ = [0,1,1,0],

    same_length(Features, ExampleA),
    Positives = [ExampleA,ExampleB,ExampleC],
    Negatives = [ExampleD,ExampleE,ExampleQ],
    [TP,FP] ins 0..3, % (in this case)
    Value #= TP-FP,
    labeling([max(Value)], [TP,FP]),
    covers_number(Features, Positives, TP),
    covers_number(Features, Negatives, FP),
    labeling(Features).

covers_number(Features, Examples, Number):-
    maplist(covers_(Features), Examples, Numbers),
    sat(card([Number], Numbers)).

covers_([F1,F2,F3,F4], [E1,E2,E3,E4], Covered) :-
    sat(Covered =:= ((F1=:=E1)*(F2=:=E2)*(F3=:=E3)*(F4=:=E4))).
于 2015-09-14T13:23:00.280 回答