0

我的问题是在这里找到的扩展：Construct new variable from given 5 categorical variables in Stata

我是 R 用户，一直在努力适应 Stata 语法。此外，我已经习惯了能够在线搜索 R 文档/示例，并且没有找到尽可能多的 Stata 资源，所以我来到了这里。

我有一个数据集，其中行代表个人，列记录这些人的各种属性。有 5 个分类变量（白人、西班牙裔、黑人、亚洲人、其他）具有二进制响应数据，0 或 1（“否”或“是”）。我想使用 spinplots 包创建种族与响应数据的马赛克图。但是，我相信我必须首先将所有 5 个分类变量组合成一个具有 5 个级别的分类变量，以维护标签（这样我就可以看到每个种族的响应率。）我一直在玩 egen 函数但没有无法让它工作。任何帮助，将不胜感激。

编辑：添加了对我的数据外观以及我希望它的外观的描述。

我现在的数据：

person_id,black,asian,white,hispanic,responded

1,0,0,1,0,0

2,1,0,0,0,0

3,1,0,0,0,1

4,0,1,0,0,1

5,0,1,0,0,1

6,0,1,0,0,0

7,0,0,1,0,1

8,0,0,0,1,1

我想要的是通过制表命令生成一个表格以进行以下操作：

respond, black, asian, white, hispanic
responded to survey |    20, 30, 25, 10, 15

did not respond     |    15, 20, 21, 23, 33
4

1 回答 1

0

您似乎想要一个指示变量而不是多个 {0,1} 虚拟变量。最简单的方法可能是循环；另一种选择是使用cond()生成一个新的指示变量（请注意，您可能想要捕获所有种族虚拟变量都0在“其他”组中的受访者），标记其值（以及 的值responded），然后创建您的频率桌子：

clear
input person_id black asian white hispanic responded
1 0 0 1 0 0
2 1 0 0 0 0
3 1 0 0 0 1
4 0 1 0 0 1
5 0 1 0 0 1
6 0 1 0 0 0
7 0 0 1 0 1
8 0 0 0 1 1
9 0 0 0 0 1
end

gen race = "other"
foreach v of varlist black asian white hispanic {
    replace race = "`v'" if `v' == 1
}

label define race2 1 "asian" 2 "black" 3 "hispanic" 4 "white" 99 "other"
gen race2:race2 = cond(black == 1, 1, ///
                cond(asian == 1, 2, ///
                cond(white == 1, 3, ///
                cond(hispanic == 1, 4, 99))))

label define responded 0 "did not respond" 1 "responded to survey"
label values responded responded
tab responded race

结果

                    |                          race
          responded |     asian      black   hispanic      other      white |     Total
--------------------+-------------------------------------------------------+----------
    did not respond |         1          1          0          0          1 |         3 
responded to survey |         2          1          1          1          1 |         6 
--------------------+-------------------------------------------------------+----------
              Total |         3          2          1          1          2 |         9

tab responded race2以不同的顺序产生相同的结果（通过实际值race2而不是值标签的字母顺序）。

于 2015-09-14T12:34:06.153 回答