3

我从 JSON 文件中得到以下字符串：

39468856,

现在，我想用这个数字来计算.. 因此，我必须,在最后删除。

此时我使用以下代码：

for /f "skip=24 tokens=2" %%a in (text.txt) do ( 

Set %%a=%%a:~0,1%
echo %%a

SET /a b=a*2
echo %%a
@echo Uebertragen in 10s:

echo %%a bytes

)

对Set %%a=%%a:~0,1%我不起作用..也不是SET /a b=a*2（可能是因为,它）。

请在这件事上给予我帮助...

提前致谢

4

1 回答 1

4

在没有看到完整代码和输入文件的情况下，这些可能是一些最简单的解决方案。

for /f "skip=24 tokens=2" %%a in (text.txt) do for %%b in (%%a) do set /a "b=%%b*2"
echo %b%

for此选项使用第二个循环删除作为分隔符处理的逗号。

for /f "skip=24 tokens=2" %%a in (text.txt) do 2>nul set /a "b=2*%%a"
echo %b%

在这种情况下，操作数的顺序已经改变，错误输出（逗号仍然存在）被丢弃。

如果输入文件数据允许，也许可以使用

for /f "skip=24 tokens=2 delims=, " %%a in (text.txt) do set /a "b=%%b*2"
echo %b%

在 中包含逗号作为分隔符for /f，标记器将丢弃它，并且逗号不会包含在检索到的数据中。

在所有情况下，由于echo已经从设置变量的代码块中移出，因此不需要延迟扩展。

但是，也许这些选项都不能使用。那么你最好的选择是使用延迟扩展

setlocal enabledelayedexpansion
for /f "skip=24 tokens=2" %%a in (text.txt) do ( 
    for %%b in (%%a) do set /a "b=%%b*2"
    echo !b!
)

或者，使用原始子字符串方法

setlocal enabledelayedexpansion
for /f "skip=24 tokens=2" %%a in (text.txt) do ( 
    set "b=%%a"

    rem Any of these could work
    set "b=!b:~0,-1!"
    set "b=!b:,=!"

    set /a "b*=2"
    echo !b!
)
于 2015-09-11T10:51:40.070 回答