8

我在 ReadMode('cbreak') 中使用 Term::ReadKey 读取单个字符并根据输入执行操作。这适用于除箭头键之外的所有其他键。按下箭头键时，该动作执行了 3 次，我理解这是因为箭头键转换为 '^[[A' 等...

如何将箭头键转换为 ReadKey 可以解释的任意单个值？

我尝试了以下代码，但它不起作用：

use Term::ReadKey;

ReadMode('cbreak');

my $keystroke = '';

while ($keystroke ne 'h') {

    print "Enter key: "; 

    #Read user keystroke 
    $keystroke = ReadKey(0);

    chomp($keystroke);


    if(ord($keystroke) == 27) {
         $keystroke = ('0');
    }
}

这是我基于建议的代码：

use Term::RawInput;
use strict;
use warnings;

my $keystroke = '';
my $special = ''; 

while(lc($keystroke) ne 'i' && lc($keystroke) ne 't'){

    my $promptp = "Enter key: ";

    ($keystroke,$special) = rawInput($promptp, 1);

    if ($keystroke ne '') {
        print "You hit the normal '$keystroke' key\n";
    } else {
        print "You hit the special '$special' key\n";
    }

    chomp($keystroke);

    $keystroke = lc($keystroke);
}

if($keystroke eq 'i') {
    #Do something
}

if($keystroke eq 't') {
    #Do something
}

现在，无论我按什么，我都无法退出这个循环

这是输出：

Enter key: 
Enter key:
Enter key: You hit the normal 't' key

#Proceeds to function
4

4 回答 4

3

这是我的工作解决方案...

use Term::ReadKey;

ReadMode('cbreak');

{
    #Temporarily turn off warnings so no messages appear for uninitialized $keystroke
    #that for some reason appears for the if statement
    no warnings;

    my $keystroke = '';

    while ($keystroke ne 'h') {

        print "\nEnter key: ";

        #Read user keystroke 
        $keystroke = ReadKey(0);

        #The first character for the arrow keys (ex. '^[[A') evaluates to 27 so I check for 
        #that
        if(ord($keystroke) == 27) {
            #Flush the rest of the characters from input buffer
            #This produces an 'Use of uninitialized value...' error
            #for the other two characters, hence 'no warnings' at the beginning.
            #This will ignore the other 2 characters and only cause a single iteration
            while( defined ReadKey(-1) ) {}
        }
    ReadMode 0;
    }
}
于 2015-09-11T00:03:24.180 回答
2

Term::RawInput并没有涵盖所有内容，但对于这项任务来说这是一个很好的开始：

use Term::RawInput;
my ($keystroke,$special) = rawInput("", 1);
if ($keystroke ne '') {
    print "You hit the normal '$keystroke' key\n";
} else {
    print "You hit the special '$special' key\n";
}
于 2015-09-09T22:46:06.550 回答
2

如果您想阅读“按键”的高级语义概念，而不是“来自终端的字节”的低级概念，您将需要一些可以为您解析和收集这些多字节序列的东西。

对于这类任务，我写了Term::TermKey：

use Term::TermKey;

my $tk = Term::TermKey->new( \*STDIN );

print "Press any key\n";

$tk->waitkey( my $key );

print "You pressed: " . $tk->format_key( $key, 0 );
于 2015-09-10T09:23:40.137 回答
1

根据mob答案，使用Term::RawInput，我做了这个脚本来模拟更复杂的输入交互。最重要的区别是使用'rawInput'：mob建议：rawInput("",1)，我发现实际使用rawInput("> ")（不带第二个参数）使事情更容易使用，并且提示“>”更有用。

此代码接受命令和特殊键。此外，它可以很好地用作系统的交互式外壳。

DELETE键将删除所有字符和BACKSPACE单个字符。ESC将退出外壳。您可以添加更多键以包括箭头或其他任何东西来执行特殊功能。此代码将打印出任何未包含在其中的特殊键if..elsif（因此您知道需要添加什么）。

use warnings;
use strict;
use Term::RawInput;

sub out {
    my $out = shift;
    print "[ $out ]\n";
}

do {
    my ($keystroke,$special) = rawInput("> ");
    if($special eq 'ESC') {
        print "\n";
        exit;
    } elsif($special eq 'ENTER') {
        out($keystroke);
    } elsif($special ne 'DELETE') {
        if ($keystroke ne '') {
            out($keystroke);
        } else {
            print "'$special' key is not associated\n";
        }
    }
} while(1);

你可以在“out”里面实现你的命令；

于 2016-07-26T04:46:43.503 回答