2

我有一个代码，当使用 RHS 上的结构构造函数对 LHS 上的未分配可分配对象进行分配时，我手头的所有编译器都会出现段错误。结构（派生类型）本身具有重载赋值。我认为，LHS 的自动重新分配应该在调用分配例程之前发生，但似乎并非如此。

在代码下方，演示了问题。取消注释分配语句使一切正常，但我不明白为什么在这种情况下需要显式分配。有趣的是，如果我删除了重载的分配，事情也会正常进行。

有什么提示吗？

module dummy
  implicit none

  type :: DummyType
    integer :: ii
  contains
    procedure :: assignDummyType
    generic :: assignment(=) => assignDummyType
  end type DummyType

  interface DummyType
    module procedure DummyType_init
  end interface DummyType

contains

  function DummyType_init(initValue) result(this)
    integer, intent(in) :: initValue
    type(DummyType) :: this
    this%ii = initValue
  end function DummyType_init

  subroutine assignDummyType(this, other)
    class(DummyType), intent(out) :: this
    type(DummyType), intent(in) :: other
    this%ii = other%ii + 1
  end subroutine assignDummyType
end module dummy

program test_dummy
  use dummy
  implicit none

  type(DummyType), allocatable :: aa

  !allocate(aa)   ! Should be covered via automatic reallocation...
  aa = DummyType(42)

end program test_dummy
4

1 回答 1

4

最近有一个关于 comp.lang.fortran 的讨论来处理这个话题。

赋值语句要么是内在赋值，要么是定义赋值。内在分配允许[重新]分配左侧，定义分配不允许。

当您为分配通用标识符提供一个过程时，您的分配就是定义的分配。对应于左侧的参数的特性则要求分配左侧。

于 2015-09-08T09:36:58.467 回答