8

我试图让FormidableLabs/radium · GitHubreagent-project/reagent · GitHub一起工作,但我走到了死胡同。

我能够通过create-class像这样的“破解”试剂功能使其部分工作(它几乎与原始相同,我只是添加了js/Radium包装器)。

(ns myproject.components.radium
  (:require [reagent.core :as r]
            [reagent.impl.component :as c]
            [reagent.impl.util :as util]
            [reagent.interop :refer-macros [.' .!]]))

(defn create-class
  [body]
  (assert (map? body))
  (let [
        spec (c/cljsify body)
        res (js/Radium (.' js/React createClass spec))
        ;res (.' js/React createClass spec)
        f (fn [& args]
            (r/as-element (apply vector res args)))]
    (util/cache-react-class f res)
    (util/cache-react-class res res)
    f))

然后我为这样的组件制作了函数

(defn radium []
  (create-class
    {:reagent-render
     (fn []
       [:button {:style
                 [{:backgroundColor             "red"
                   :width                       500
                   :height                      100
                   "@media (min-width: 200px)" {:backgroundColor "blue"}
                   ":hover"                     {:backgroundColor "green"}}
                  {:height 200}]}
        "Heres something"])}))

我在其他一些试剂渲染功能中使用它,例如:[radium/radium]

  • 因此,将样式向量合并在一起效果很好(这就是 Radium 功能)。
  • 媒体查询也有效,但仅在第一次渲染时,当我更改屏幕尺寸时它不会动态反应。
  • :hover :focus :active根本不起作用

我正在挖掘镭代码以找出问题所在。好的迹象是 Radium 正确地为组件分配onMouseEnter onMouseLeave了 props 并将组件的:hover状态设置为 true。

这会被正确触发:https ://github.com/FormidableLabs/radium/blob/master/modules/resolve-styles.js#L412

问题是该render函数根本没有被触发,该函数应该基于新状态(由 Radium 更改)重新渲染组件。这个render函数: https ://github.com/FormidableLabs/radium/blob/master/modules/enhancer.js#L22 当我运行 JS Radium 示例(没有 Clojurescript 和 Reagent)时,这个渲染函数会在每个onMouseEnter onMouseLeave. 完全不用试剂。

当组件状态发生变化时,Reagent 是否会以某种方式阻止重新渲染?

4

1 回答 1

5

我已经翻译了要与 Reagent 一起使用的基本按钮 Radium 示例:

(def Radium js/Radium)

(def styles {:base {:color "#fff"
                    ":hover" {:background "#0A8DFF"}}
             :primary {:background "#0074D9"}
             :warning {:background "#FF4136"}})

(defn button
  [data]
  (let [kind (keyword (:kind data))]
    [:button
     {:style (clj->js [(:base styles)
                       (kind styles)])}
     (:children data)]))

(def btn (Radium. (reagent/reactify-component button)))

(def rbtn (reagent/adapt-react-class btn))

(defn hello-world
  []
  [:div
   [rbtn {:kind :primary} "Hello Primary"]
   [rbtn {:kind :warning} "Hello Warning"]])

关键是我将button试剂组件转换为 React 组件(使用reactify-component),然后将其通过 Radium,然后将其转换回我在试剂中消耗的东西(使用adapt-react-class)。

在我的示例中,hover有效。

希望这可以帮助。

我已将工作版本放在GitHub 上

于 2016-07-04T11:31:07.100 回答