1

在 Delphi XE8 中，我试图SetParameter从 OmniThreadLibrary 将数组传递给 OTL 任务：

implementation

type
  TCookie = record
    Name:    string;
    Value:   string;
    ExpDate: string;
    ModDate: string;
  end;

  TCookieArray = array of TCookie;

var
  CurCookies: TCookieArray;

procedure TForm1.btnStartTaskClick(Sender: TObject);
begin
  SetLength(CurCookies, 2);
  CurCookies[0].Name  := 'username';
  CurCookies[0].Value := 'Paul';
  CurCookies[1].Name  := 'password';
  CurCookies[1].Value := 'none';

  FGetCookieDetailsTask := CreateTask(GetCookieEntries, 'GetCookieEntries')
    .MonitorWith(OTLMonitor)
    // Compiler complaint:
    .SetParameter('CookiesArray', TOmniValue.FromArray<TCookieArray>(CurCookies))
    .Run;
end;

编译器抱怨 SetParameter 行：

[dcc32 Error] Unit1.pas(310): E2010 Incompatible types:
'System.TArray<Unit1.TCookieArray>' and 'TCookieArray'

不幸的是，OTL 书中没有关于如何使用FromArrayinSetParameter将数组传递给任务的示例。

那么如何做到这一点呢？

编辑：ba__friend 要求我在他的回答的评论中显示我的解决方案的源代码：

  FGetCookieDetailsTask := CreateTask(GetCookieEntries, 'GetCookieEntries')
    .MonitorWith(OTLMonitor)
    // Now no compiler complaint:
    .SetParameter('CookiesArray', CurCookies)
    .Run;

procedure GetCookieEntries(const task: IOmniTask);
var
  TaskCookies, HostCookies: TCookieArray;
begin
  HostCookies := task.Param['CookiesArray'];
  TaskCookies := Copy(HostCookies, 0, Length(HostCookies));
4

1 回答 1

2

您的代码中有两个问题。

1)TCookieArray必须声明为

TCookieArray = TArray<TCookie>;

从编译器的角度来看，array of T和TArray<T>（遗憾的是）不是一回事。

2)FromArray<T>期望类型T是数组项类型，而不是数组类型（请参阅OtlCommon），因此您必须将其从

TOmniValue.FromArray<TCookieArray>

至

TOmniValue.FromArray<TCookie>

要从任务访问此数组，请调用：

var
  cookies: TCookieArray;

cookies := task.Param['CookiesArray'].ToArray<TCookie>;

旁注：事情应该是这样工作的。然而，在 OTL 直到（包括）3.04b 中，记录类型在ToArray<T>和中没有被正确处理FromArray<T>。刚刚提交给GitHub的修复程序。

如果要手动修复副本，则需要进行两项修改。

在TOmniValue.CastFrom<T>, 这个块

if ds = 0 then // complicated stuff
  {$IFDEF OTL_ERTTI}

应该改为

if ds = 0 then // complicated stuff
  if ti^.Kind = tkRecord then
    Result.SetAsRecord(CreateAutoDestroyObject(
      TOmniRecordWrapper<T>.Create(value)))
  else
    {$IFDEF OTL_ERTTI}

在TOmniValue.CastTo<T>, 后面的块

if ds = 0 then // complicated stuff
  {$IFDEF OTL_ERTTI}

应该改为

if ds = 0 then // complicated stuff
  if ti.Kind = tkRecord then
    Result := TOmniRecordWrapper<T>(CastToRecord.Value).Value
  else
    {$IFDEF OTL_ERTTI}
于 2015-08-29T16:03:24.257 回答