2

也就是让事件循环处理当前队列中的事件。在 VBA 中，调用名为DoEvents.

我想在 Perl 中做到这一点。最好在 AnyEvent 中执行此操作，因为我有一个用它编写的脚本。但我在文档中找不到任何类似的功能。

我天真地尝试用 condvar 实现它，因为文档说recv调用事件循环，但它失败了，这里是示例代码：

use strict;
use warnings;

use AnyEvent;
use AnyEvent::Strict;

sub _long_task;

my $t1 = AE::timer 0, 3, sub{print"task 1, with interval 3 seconds\n";};
my $t2 = AE::timer 0, 7, sub{print"task 2, with interval 7 seconds\n";};
my $t3 = AE::timer 0, 11, sub{print"task 3, with interval 11 seconds\n";};
my $t_long = AE::timer 0, 0, \&_long_task;

sub DoEvents()
{
    my $cv = AE::cv;
    my $t = AE::timer 0, 0, sub { $cv->send; };
    $cv->recv;
}

sub _long_task {
    print"long task: ENTERING\n";
    for(1..5) {
        print"long task: doing some work for 2 seconds\n";
        sleep 2;
        print"long task: calling DoEvents\n";
        DoEvents();
    }
    print"long task: EXITING, resheduling after 10 seconds\n";
    $t_long = AE::timer 10, 0, \&_long_task;
}

AE::cv->recv;

输出是：

task 1, with interval 3 seconds
task 2, with interval 7 seconds
task 3, with interval 11 seconds
long task: ENTERING
long task: doing some work for 2 seconds
long task: calling DoEvents
AnyEvent::CondVar: recursive blocking wait attempted at C:\Users\andreyi\Desktop\try_event_loop.pl line 18.

更新： AnyEvent.pm 中有几行：

  $WAITING
     and Carp::croak "AnyEvent::CondVar: recursive blocking wait attempted";

如果您对它们发表评论，则 DoEvents() 有效。

但是，最好有不涉及修改此 CPAN 模块的解决方案。

4

1 回答 1

1

每个问题至少有一个简单的解决方案（有时它是一个肮脏的黑客）。

就我而言，这似乎有效。我将它添加到生产代码中。

BEGIN { our $orig_Carp_croak = \&Carp::croak; }
sub DoEvents()
{
    my $cv = AE::cv;
    my $t = AE::timer 0, 0, $cv;
    no warnings 'redefine';
    local *Carp::croak = sub{
        (caller 1)[3] eq 'AnyEvent::CondVar::Base::recv'
            && $_[0] =~ /recursive blocking wait attempted/
            && return;
        goto \&{our $orig_Carp_croak};
    };
    $cv->recv;
}

更新： 对于所有调用 DoEvents 的回调，您需要确保它们不会被重新输入。像这样：

our $entered_callbacks = {};
# ...
sub some_callback {
    $entered_callbacks->{some_callback} && return;
    local $entered_callbacks->{some_callback} = 1;
    ...;
}

循环 EV 和 AnyEvent::Loop 的缺陷是回调仅在返回时才从队列中删除，而不是在调用之前。它使事件循环对于重新进入不安全。

于 2015-08-26T11:05:11.077 回答