1

我正在尝试使用 XSL 将 XML 文件转换为漂亮的 HTML 表，但我一生都无法弄清楚如何正确排列所有列。我发现了一个类似的问题（Convert XML List to HTML Table Using XSL），它提供了丰富的信息（我对 XSL 很陌生，所以每一点都有帮助），但我的 XML 的结构更...不规则：

<?xml version="1.0"?>
<root>
    <Group>
        <Type>Type1</Type>
        <Desc>Desc1</Desc>
        <Name>Name1</Name>
    </Group>
    <Group>
        <Type>Type2</Type>
        <Name>Name2</Name>
        <State>State2</State>
    </Group>
    <Group>
        <Type>Type3</Type>
        <State>State3</State>
        <Country>Country4</Country>
    </Group>
</root>

有没有一种好方法可以把它变成一个格式良好的表格？我希望它像这样在 XML 上工作，就好像我们曾经向其中一个 Group 元素添加一个新字段一样，我不希望它们必须向每个其他元素添加相同的标签（尽管如果有另一种好方法可以自动将所有丢失的子元素添加到其他 Group 元素中存在的 Group 元素中，那也很好，也许使用可以先运行的第二个 XSLT）。此 XML 没有支持模式，但如果有帮助，可以制作一个。

抱歉，如果之前已经回答过这个问题，除了提到的问题之外，我找不到任何更接近的东西，也没有关于如何将丢失的子元素添加到元素的信息。

4

2 回答 2

1

首先，这并不简单。如果您是 XSLT 的新手，那么这可能不是您从事的最佳项目。

为了理解以下解决方案，您需要熟悉使用keys，以及Muenchian 分组技术。

XSLT 1.0

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" omit-xml-declaration="yes" version="1.0" encoding="utf-8" indent="yes"/>

<xsl:key name="col-by-name" match="/root/Group/*" use="name()" />
<xsl:key name="cell-by-rowXcol" match="/root/Group/*" use="concat(generate-id(..), '|', name())" />

<xsl:template match="/root">
    <xsl:variable name="distinct-columns" select="Group/*[count(. | key('col-by-name', name())[1]) = 1]"/>
    <table border="1">
        <thead>
            <tr>
                <xsl:for-each select="$distinct-columns">
                    <th><xsl:value-of select="name()"/></th>
                </xsl:for-each>
            </tr>
        </thead>
        <tbody>
            <xsl:for-each select="Group">
            <xsl:variable name="row" select="generate-id()" />
                <tr>
                    <xsl:for-each select="$distinct-columns">
                        <td>
                            <xsl:value-of select="key('cell-by-rowXcol', concat($row, '|', name()))" />
                        </td>
                    </xsl:for-each>
                </tr>
            </xsl:for-each>
        </tbody>
    </table>
</xsl:template>

</xsl:stylesheet>

结果（渲染）：

在此处输入图像描述

在 XSLT 2.0 中，您可以使用distinct-values()函数而不是 Muenchian 分组。

于 2015-08-21T17:53:16.863 回答
0

这是我对 XSLT 2.0 解决方案的尝试：

<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
    <xsl:output method="html" version="5.0" encoding="UTF-8" indent="yes" />

    <xsl:variable name="col-names" select="distinct-values(root/Group/*/node-name(.))"/>

    <xsl:template match="root">
        <table>
            <thead>
                <tr>
                    <xsl:for-each select="$col-names">
                        <th>
                            <xsl:value-of select="."/>
                        </th>
                    </xsl:for-each>
                </tr>
            </thead>
            <tbody>
                <xsl:apply-templates select="Group"/>                
            </tbody>
        </table>
    </xsl:template>

    <xsl:template match="Group">
        <tr>
            <xsl:variable name="this" select="."/>
            <xsl:for-each select="$col-names">
                <td>
                    <xsl:value-of select="$this/*[node-name(.) eq current()]"/>
                </td>
            </xsl:for-each>
        </tr>
    </xsl:template>
</xsl:transform>
于 2015-08-21T17:59:50.693 回答