9

我有一些复杂的 XSLT 2.0 转换。我试图找出是否有通用方法来确保不输出空标签。所以......从概念上讲，递归删除所有空标签的最后一个处理阶段。我知道这可以通过一个单独的 XSLT 来完成，该 XSLT 只过滤掉空标签，但我需要将它们全部打包在一个单独的 XSLT 中。

4

1 回答 1

8

这个 XSLT 2.0 转换说明了如何进行多通道（在本例中为 2 通道）处理：

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*" mode="#all">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*" mode="#current"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="/">
   <xsl:variable name="vPass1">
     <xsl:apply-templates/>
   </xsl:variable>

   <xsl:apply-templates select="$vPass1/*" mode="non-empty"/>
 </xsl:template>

 <xsl:template match="text()[xs:integer(.) mod 2 eq 0]"/>

 <xsl:template match="*[not(node())]" mode="non-empty"/>
</xsl:stylesheet>

应用于此 XML 文档时：

<nums>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
</nums>

它在第一遍中创建一个结果文档（在$vPass1变量中捕获），其中所有<num>内容甚至整数的元素都被剥离其内容并为空。然后，在以特定模式应用的第二遍中，删除所有空元素。

转换的结果是：

<nums>
   <num>01</num>
   <num>03</num>
   <num>05</num>
   <num>07</num>
   <num>09</num>
</nums>

请注意模式的使用，以及特殊模式#all和#current。

更新： OP 现在希望在评论中删除“递归”“所有没有非空后代的节点”。

这可以使用不显式递归更简单地实现。只是改变：

 <xsl:template match="*[not(node())]" mode="non-empty"/>

到：

 <xsl:template match="*[not(descendant::text())]" mode="non-empty"/>
于 2010-07-08T01:06:05.400 回答