0

我在尝试运行使用过程的简单 PL/SQL 程序时遇到上述错误。不知道出了什么问题，请帮忙。

declare
    create or replace procedure palindrome (x in number,y out number) is
    i integer;
    j integer;
    k integer:=0;
begin
    i:=x;
    while i>0
    loop
        j:=mod(i,10);
        k:=k*10+j;
        i:=i/10;
    end loop;
    y:=k;
end;
begin
    x integer:=121;
    y integer;
    palindrome(x,y);
    dbms_output.put_line(y);
end;

/错误在第 2 行：

ORA-06550：第 2 行，第 2 列：PLS-00103：在预期以下情况之一时遇到符号“CREATE”：begin function pragma procedure subtype type current cursor delete exists prior

4

2 回答 2

0

修改您的代码。

  create or replace procedure palindrome (x in number,y out number) is
    i integer;
    j integer;
    k integer:=0;

begin
    i:=x;
    while i>0
    loop
        j:=mod(i,10);
        k:=k*10+j;
        i:=i/10;
    end loop;
    y:=k;
    dbms_output.put_line(y);
end;

/

执行该程序

declare
y number;
begin
 palindrome(133,y);
end;
于 2015-08-13T11:39:29.590 回答
0

只有DECLARE在创建包含变量声明的匿名 PL/SQL 块时才需要。当您创建命名过程/函数/包时，您的CREATE OR REPLACE ...语句将代替DECLARE. 该语句和相应语句之间的任何内容BEGIN都称为声明部分。

如果您尝试创建一个命名过程，然后您可以使用另一个 PL/SQL 匿名块调用该过程，则不是特别清楚，在这种情况下，您会这样做：

create or replace procedure palindrome (x in number,y out number) is
    i integer;
    j integer;
    k integer:=0;
begin
    i:=x;
    while i>0
    loop
        j:=mod(i,10);
        k:=k*10+j;
        i:=i/10;
    end loop;
    y:=k;
end;
/

declare
    x integer := 121;
    y integer;
begin
    palindrome(x,y);
    dbms_output.put_line(y);
end;
/

或者如果你试图在匿名 PL/SQL 中声明一个过程，在这种情况下你会这样做：

declare
    x integer := 121;
    y integer;

    procedure palindrome (x in number, y out number) is
        i integer;
        j integer;
        k integer := 0;
    begin
        i := x;
        while i > 0
        loop
            j := mod(i,10);
            k := k*10 + j;
            i := i/10;
        end loop;
        y := k;
    end palindrome;
begin
    palindrome(x,y);
    dbms_output.put_line(y);
end;
/
于 2015-08-13T11:47:29.110 回答