oracle - 有没有办法使用utl_file从oracle plsql中超过32000的数据生成csv

Question

.. FILE1 := UTL_FILE.FOPEN('DIR','cg.csv','w',32000); .. 我们正在生成一个 csv 文件，该文件具有视图的许多列的连接值。有没有办法使用utl_file从oracle plsql中超过32000的数据生成csv

Answer 1

根据Oracle 的功能文档UTL_FILE.FOPEN：

FOPEN max_linesize 参数必须是 1 到 32767 范围内的数字

因此您可以将其增加到 32767，但不能再增加。

您可能需要考虑创建多个文件。

Answer 2

declare
FILEHANDLE           UTL_FILE.FILE_TYPE;
WRITEMESSAGE   varchar2(200);
longLine varchar2(32767);
newline char(2) :=  CHR(13) || CHR(10);
begin
longLine :=  LPAD('aaaa', 32766,'x');
FILEHANDLE        := UTL_FILE.FOPEN('XMLDIR','lonLineFile.txt','wb',32767);
for i in 1 .. 5 loop
  UTL_FILE.PUT_RAW (filehandle,UTL_RAW.CAST_TO_RAW (longLine),true); 
  UTL_FILE.PUT_RAW (filehandle,UTL_RAW.CAST_TO_RAW (longLine),true); 
  UTL_FILE.PUT_RAW (filehandle,UTL_RAW.CAST_TO_RAW (longLine),true); 
  UTL_FILE.PUT_RAW (filehandle,UTL_RAW.CAST_TO_RAW (newline),true); 
end loop;
  UTL_FILE.FCLOSE(filehandle);
end;
/

以“wb”写入字节模式打开文件。接下来将 raw 写入文件和行尾字符。

Answer 3

是的，有一种方法 - 使用clob数据类型而不是varchar2. clob PL/SQL 中的最大大小为 128TB。

在您的 PL/SQL 代码中，首先将数据收集到临时 clob。第二次迭代块中的 clob 并将它们提供给utl_file.

下面是一个随机的互联网代码片段，它将任意 clob 写入用户定义的文件：

procedure save (
  p_text in clob,
  p_path in varchar2,
  p_filename in varchar2
) as
  v_lob_temp blob;
begin
  --
  -- exit if any parameter is null
  --
  if    p_text is null
     or p_path is null
     or p_filename is null then
    return;
  end if;

  --
  -- convert a clob to a blob
  --
  declare
    v_dest_offset pls_integer := 1;
    v_src_offset pls_integer := 1;
    v_lang_context pls_integer := dbms_lob.default_lang_ctx;
    v_warning pls_integer := dbms_lob.no_warning;
  begin
    dbms_lob.createtemporary(lob_loc => v_lob_temp,
                             cache => true,
                             dur => dbms_lob.call);

    dbms_lob.converttoblob(dest_lob => v_lob_temp,
                           src_clob => p_text,
                           amount => dbms_lob.lobmaxsize,
                           dest_offset => v_dest_offset,
                           src_offset => v_src_offset,
                           blob_csid => dbms_lob.default_csid,
                           lang_context => v_lang_context,
                           warning => v_warning);
    -- TODO raise (what?) when warning
  end;

  --
  -- write a blob to a file
  --
  declare
    v_lob_len pls_integer;
    v_fh utl_file.file_type;
    v_pos pls_integer := 1;
    v_buffer raw(32767);
    v_amount pls_integer := 32767;
  begin
    v_fh := utl_file.fopen(p_path, p_filename, 'wb', 32767);

    v_lob_len := dbms_lob.getlength(v_lob_temp);

    while v_pos < v_lob_len loop
      dbms_lob.read(v_lob_temp, v_amount, v_pos, v_buffer);

      utl_file.put_raw(file => v_fh,
                       buffer =>v_buffer,
                       autoflush => false);

      v_pos := v_pos + v_amount;
    end loop;

    utl_file.fclose(v_fh);
    dbms_lob.freetemporary(v_lob_temp);
  end;

end;