qt - 从 Delegate 访问 Listview currentIndex

Question

我有一个 QML ListView，委托从另一个文件加载它的组件。单击委托项目时，我想更新ListView. CurrentIndex和highlight选定的项目。

当我明确设置id. ListView但是，由于我也想将 delegateComponent用于 other ListView，因此我正在努力寻找一种通用的方式来ListView.currentIndex从 delegate中访问Component。

这是代码：

main.qml

import QtQuick 2.4
import QtQuick.Controls 1.3
import QtQuick.Window 2.2
import QtQuick.Dialogs 1.2

ApplicationWindow {
    title: qsTr("Hello World")
    width: 640
    height: 480
    visible: true

    ListModel {
        id: contactsModel
        ListElement {
            name: "Bill Smith"
        }
        ListElement {
            name: "John Brown"
        }
        ListElement {
            name: "Sam Wise"
        }
    }

    ListView{
        id: contactsView
        anchors.left: parent.left
        anchors.top: parent.top
        width: parent.width
        height: parent.height
        orientation: Qt.Vertical
        spacing: 10
        model: contactsModel
        delegate: Contact{}
    }
}

Contact.qml（委托使用的组件）

import QtQuick 2.0

Component{
    id: contact
    Rectangle{
        width: 200
        height: 50
        color: ListView.isCurrentItem ? "#003366" : "#585858"
        border.color: "gray"
        border.width: 1

        MouseArea{
            anchors.fill: parent
            onClicked: {
                ListView.currentIndex = index; // <---- does not work
                //  contactsView.currentIndex = index; // <---- Works
            }
        }

        Text{
            anchors.centerIn: parent
            color: "white"
            text: name
        }
    }
}

非常感谢任何帮助！

score 15 · Accepted Answer

这里有两个问题：

您需要ListView使用从中访问它们的项目的名称来限定的附加属性。
该currentIndex属性是项类型的属性ListView，而不是附加的属性对象。

要修复它们，首先更改此：

ListView.currentIndex = index;

对此：

delegate.ListView.view.currentIndex = index;

然后给你的代表一个id：

Component {
    id: contact

    Rectangle {
        id: delegate
    // ...
}

文档的示例用法部分（部分）证明了这一点：

ListView 将许多属性附加到委托的根项，例如 ListView:isCurrentItem。在以下示例中，根委托项可以直接以 ListView.isCurrentItem 访问此附加属性，而子 contactInfo 对象必须将此属性称为 wrapper.ListView.isCurrentItem。

score 4 · Accepted Answer

使用附加属性ListView.view：

此附加属性包含管理此委托实例的视图

小例子：

import QtQuick 2.4
import QtQuick.Window 2.2
import QtQuick.Layouts 1.1

Window {
    width: 600
    height: 400
    visible: true

    Component {
        id: listDelegate
        Rectangle {
            height: 30
            width: parent.width
            color:  ListView.isCurrentItem ? "orange" : "white"
            property var view: ListView.view
            property int itemIndex: index
            Text { anchors.centerIn: parent; text: name }
            MouseArea {
                anchors.fill: parent
                onClicked: {
                    view.currentIndex = itemIndex;
                }
            }
        }
    }

    RowLayout {
        anchors.fill: parent
        ListView {
            Layout.minimumWidth: parent.width / 2
            Layout.fillHeight: true
            model: ListModel {
                ListElement {name: "item1.1"}
                ListElement {name: "item1.2"}
                ListElement {name: "item1.3"}
            }
            delegate: listDelegate
        }
        ListView {
            Layout.minimumWidth: parent.width / 2
            Layout.fillHeight: true
            model: ListModel {
                ListElement {name: "item2.1"}
                ListElement {name: "item2.2"}
                ListElement {name: "item2.3"}
            }
            delegate: listDelegate
        }
    }
}

qt - 从 Delegate 访问 Listview currentIndex

2 回答 2

Related

Reference