0

在 Common Lisp 中，有 ; 的顺序形式(do *vars* *test* *body*)。就像let 's 顺序并行一样let*，它*vars*一次处理一个，因此您可以参考以前定义的变量，如下所示：

(do* ((a '(1 2 3) (cdr a))
      (b (mapcar (lambda (x) (1+ x)) a) (cdr b)))
     ((= 1 1) (list 'a a 'b b)))
; (a (1 2 3) b (2 3 4))

在 Scheme、AFAIK 中，没有相关函数或宏。有do，但没有do*。我一直在尝试do*为 Chicken Scheme 编写一个实现，但到目前为止，我一直在努力取得任何进展......我想，我真的说不出来。我对鸡计划很熟悉，但我总是觉得计划宏令人困惑。

这是我到目前为止所得到的：

(##sys#extend-macro-environment
 'do*
 '()
 (##sys#er-transformer
  (lambda (form r c)
(##sys#check-syntax 'do* form '(_ #((symbol _ . #(_)) 0) . #(_ 1)))
(let* ((bindings (cadr form))
       (test (caddr form))
       (body (cdddr form))
       (do*var (r 'doloop)))
  `(let*
       ,do*var
     ,(##sys#map (lambda (b) (list (car b) (car (cdr b)))) bindings)
     (##core#if ,(car test)
        ,(let ((tbody (cdr test)))
           (if (eq? tbody '())
               '(##core#undefined)
               `(##core#begin ,@tbody) ) )
        (##core#begin
         ,(if (eq? body '())
              '(##core#undefined)
              `(##core#let () ,@body) )
         (##core#app
          ,do*var ,@(##sys#map (lambda (b)
                     (if (eq? (cdr (cdr b)) '())
                         (car b)
                         (car (cdr (cdr b))) ) )
                       bindings) ) ) ) ) ) ) ) )

但是我不断收到错误，例如doloop不是列表-目前，我得到了

Error: during expansion of (do* ...) - in `do*' - symbol expected: (do* ((a (quote (1 2 3)) (cdr a)) (b (map (lambda (x) (+ 1 x)) a) (cdr b)) ((= 1 1) (list (quote a) a (quote b) b))))

    Call history:

    <syntax>          (do* ((a (quote (1 2 3)) (cdr a)) (b (map           (lambda (x) (+ 1 x)) a) (cdr b)) ((= 1 1) (list (quote a) a...
    <eval>    (##sys#check-syntax (quote do*) form (quote (_ #((symbol _ . #(_)) 0) . #(_ 1))))     <--

这是do*来自HyerSpec的 Common Lisp 的粗略：

  (block nil        
   (let ((var1 init1)
     (var2 init2)
     ...
     (varn initn))
     declarations
     (loop (when end-test (return (progn . result)))
       (tagbody . tagbody)
       (psetq var1 step1
          var2 step2
          ...
          varn stepn))))

do* 类似，除了 let* 和 setq 分别替换了 let 和 psetq。

do*以下是 CL 中扩展的内容：

(expand-form '(do* ((a '(1 2 3) (cdr a))
        (b (mapcar (lambda (x) (1+ x)) a) (cdr b)))
           ((= 1 1) (list 'a a 'b b))))
(block nil
   (let* ((a '(1 2 3)) (b (mapcar #'(lambda (x) (declare (system::source ((x) (1+ x)))) (1+ x)) a)))
     (tagbody #:loop-5382 (if (= 1 1) (go #:end-5383)) (setq a (cdr a) b (cdr b)) (go #:loop-5382) #:end-5383 (return-from nil (list 'a a 'b b))))) ;
;t
4

1 回答 1

1

请不要使用以## 为前缀的标识符。这些不受支持，也不属于官方 API！

其次，不要试图搞乱低级宏，只需使用语法规则，它更简单、不易出错且标准化。只要您不需要破坏卫生，就应该使用它。

这是 do* 的一个示例，如果我理解正确，它将起作用：

(define-syntax do*
  (syntax-rules ()
    ((_ ((?var0 ?init0 ?inc0) ...)
         (?test ?result)
         ?body ...)
     (let* ((?var0 ?init0) ...)
       (let lp ()
         (cond (?test ?result)
               (else ?body ...
                     (set! ?var0 ?inc0) ...
                     (lp))))))))

表示为隐式重命名宏：

(define-syntax do*
  (ir-macro-transformer
   (lambda (e i c)
     (let* ((vars (cadr e))
            (test&result (caddr e))
            (test (car test&result))
            (result (cadr test&result))
            (body-exprs (cdddr e)))
       `(let* (,@(map (lambda (v) (list (car v) (cadr v))) vars))
          (let lp ()
            (cond (,test ,result)
                  (else ,@body-exprs
                        ,@(map (lambda (v) `(set! ,(car v) ,(caddr v))) vars)
                        (lp)))))))))

我希望你同意这种方式更加冗长。

于 2015-08-12T14:18:43.517 回答