1

我有一个程序在我睡觉时经常崩溃，我需要让它继续运行。所以我想我可能会编写一个监控进程列表的 vb6 应用程序，如果某些东西消失了，它将重新启动它。有谁知道一个简单的方法？

4

4 回答 4

3

您可以使用EnumProcesses列出运行时系统中的每个进程，您可以使用此声明来使用它

Public Declare Function EnumProcesses Lib "psapi.dll" ( _
                                      ByRef idProcess As Long, ByVal cb As Long, _
                                      ByRef cbNeeded As Long) As Long

在使用它之前，您应该定义一个 Long 数组作为参数传递给 EnumProcesses，并具有足够的空间来读取所有进程 ID。您可以调用 EnumProcesses 两次以发现该数组应该有多大。在第二次调用之后，您可以开始循环遍历该数组并打开进程，以这种方式获取适当使用的句柄可以告诉您进程可执行文件的名称并将该数据与您正在搜索的可执行文件的名称进行比较就完成了。否则，如果您正在寻找的是一个 DLL，例如，您可以 EnumProcessModules 为该进程句柄搜索您正在寻找的 dll 的每个正在运行的进程。EnumProcessModules 的声明是这样的

    Public Declare Function EnumProcessModules Lib "psapi.dll" ( _
                                               ByVal hProcess As Long, ByRef lphModule As Long, _
                                               ByVal cb As Long, ByRef cbNeeded As Long) As Long

你可能需要的代码是这样的

Option Explicit

Private Declare Function OpenProcess Lib "Kernel32.dll" ( _
                                    ByVal dwDesiredAccessas As Long, ByVal bInheritHandle As Long, _
                                    ByVal dwProcId As Long) As Long
Private Declare Function EnumProcesses Lib "psapi.dll" ( _
                                      ByRef lpidProcess As Long, ByVal cb As Long, _
                                      ByRef cbNeeded As Long) As Long
Private Declare Function GetModuleFileNameExA Lib "psapi.dll" ( _
                                             ByVal hProcess As Long, ByVal hmodule As Long, _
                                             ByVal moduleName As String, ByVal nSize As Long) As Long
Private Declare Function EnumProcessModules Lib "psapi.dll" ( _
                                           ByVal hProcess As Long, ByRef lphModule As Long, _
                                           ByVal cb As Long, ByRef cbNeeded As Long) As Long
Private Declare Function TerminateProcess Lib "kernel32" (ByVal hProcess As Long, ByVal uExitCode As Long) As Long
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long

Private Const PROCESS_ALL_ACCESS         As Long = &H1F0FFF

Public Function IsModuleRunning(ByVal theModuleName As String) As Boolean
    Dim aProcessess(1 To 1024)  As Long ' up to 1024 processess?'
    Dim bytesNeeded             As Long
    Dim i                       As Long
    Dim nProcesses              As Long
    Dim hProcess                As Long
    Dim found                   As Boolean

    EnumProcesses aProcessess(1), UBound(aProcessess), bytesNeeded
    nProcesses = bytesNeeded / 4
    For i = 1 To nProcesses

        hProcess = OpenProcess(PROCESS_ALL_ACCESS, False, aProcessess(i))
        If (hProcess) Then
            Dim hmodule(1 To 1024)  As Long ' no more than 1024 modules per process?'
            bytesNeeded = 0
            If EnumProcessModules(hProcess, hmodule(1), 1024 * 4, bytesNeeded) Then
                Dim nModules    As Long
                Dim j           As Long
                Dim moduleName  As String

                moduleName = Space(1024)   ' module name should have less than 1024 bytes'

                nModules = bytesNeeded / 4
                For j = 1 To nModules
                    Dim fileNameLen As Long
                    fileNameLen = GetModuleFileNameExA(hProcess, hmodule(j), moduleName, 1024)
                    moduleName = Left(moduleName, fileNameLen)
                    If Right(LCase(moduleName), Len(theModuleName)) = LCase(theModuleName) Then
                        found = True
                        Exit For
                    End If
                Next
            End If
        End If
        CloseHandle hProcess
        If found Then Exit For
    Next
    IsModuleRunning = found
End Function

Private Sub Form_Load()
    MsgBox IsModuleRunning("explorer.exe")
End Sub

函数代码有点长，但调用它是一个小函数，如果你想测试一下，你可以使用它:)

于 2008-12-05T02:17:49.430 回答
2

使用WMI。

如果您不喜欢 VB6，请在 Web 上搜索 WMI+VB6。
否则，连接 c# 和 WMI 会容易得多。

于 2008-11-25T18:17:26.763 回答
0

我使用一个运行其他程序的程序。这样，您可以轮询进程句柄以查看应用程序是否仍在运行。如果没有，您可以再次启动它。它确实需要 API 编程。

于 2008-11-26T21:38:58.947 回答
0

我使用了计划任务（每 10 分钟运行一次），使用下一个内容启动 cmd 文件：

tasklist |find "myapp.exe" >nul || c:\mypath\myapp.exe

您可以从 VB6 Shell 执行此类命令文件或仅使用任务计划程序 :)

于 2008-11-25T18:34:40.880 回答