8 
my %hash =
    two   => 2,
    three => 3,
    one   => 1,
;

for %hash.sort(*.key)>>.kv -> ($key, $value) {
    say "'$key' => '$value'";
}

%hash.sort({.key})>>.kv相当于上面的排序吗？

>>为什么这种排序在没有超提示的情况下不起作用？

4

2 回答 2

13

该sort方法返回一个List of Pairs。

由于调用.kv列表会返回index, Pair您不想要的列表列表；你不能只打电话.kv。因此，您必须通过调用每个对象上的方法来分别从列表中的Pair对象中提取键和值，这样就可以了。.kv>>.kv

你也可以.map(*.kv)改用。

>>.kv如果有意义的话，该语法允许实现将工作分散到多个线程上。
（目前 Rakudo 只是以半随机顺序完成工作，以防止人们错误地使用该功能）

通过使用子签名中的副词提取属性，还有另一种编写循环的方法：

for %hash.sort -> (:$key, :$value) {
  say "'$key' => '$value'";
}

for %hash.sort -> $pair (:$key, :$value) {
  say $pair;
  say $key === $pair.key and $value === $pair.value; # True␤
}

# :$key is short for :key($key)
for %hash.sort -> (:key($k), :value($v)) {
  say "'$k' => '$v'";
}

这对于没有创建其公共属性列表的方法的其他对象很有用

class C { has $.a; has $.b; has $.c; has $!private-value }
my $c = 5;
my $obj = C.new(:a<A>,:b(1),:$c);

given $obj -> ( :$a, :b($b), :$c) ) {
  say "$a $b $c";
}

# ignore $.a by using an unnamed scalar
given $obj -> ( :a($), :$b, :$c ) { ... }

# places any unspecified public attributes in %others
given $obj -> ( :$a, :$b, *%others ) {
  .say for keys %others; # c␤
}

# ignores any unspecified attributes
# useful to allow subclasses to add more attributes
# or to just drop any values you don't care about
given $obj -> ( :$a, :$b, *% ) { ... }

# fails because it doesn't handle the public c attribute
# in the sub-signature
given $obj -> ( :$a, :$b ) { ... }

这只是签名可能的开始。

以下所有内容在子例程和方法签名中也是允许的，可选的，对于这个例子来说完全是多余的。它在用于限制可能的候选者的多子和多方法中非常有用。

for 'one' => 1, 1/3
->
  # Type is an alias to the object type
  ::Type Any $_ # Any is the default type requirement

  # the public attributes of the object
  (
    ::A-Type Any :key(   :numerator(   $a ) ),
    ::B-Type Any :value( :denominator( $b ) ) where $b >= 1,
  )
{
  my Type $obj = $_; # new variable declared as having the same type
  my A-Type $new-a = $a;
  my B-Type $new-b = $b;

  # could have used $_.^name or .^name instead of Type.^name
  # so you don't actually have to add the alias to the signature
  # to get the name of the arguments type
  say Type.^name, ' ', $_;
  say '  ', A-Type.^name, ' ', $a;
  say '  ', B-Type.^name, ' ', $b;
}

Pair one => 1
  Str one
  Int 1
Rat 0.333333
  Int 1
  Int 3

至于 using .sort({.key})，是的，这基本上是一样的，因为在那里sort接受任何Callable。

我想指出你甚至不需要提供参数，sort因为它的默认值甚至比你给它的更聪明。

Perl 6 有许多创建和访问Callable事物的方法。因此，以下任何一项都会起作用：

*.key
{ .key } # { $_.key }
-> $_ { .key } # basically what the previous line turns into
{ $^placeholder-var.key }
sub ($_) { .key }
&a-subroutine-reference # you would have to create the subroutine though

此外，由于所有普通运算符实际上都是子例程，因此您可以在需要Callable的其他地方使用它们。（虽然我想不出一个在那个地方工作的人）

&infix:<+> # the subroutines responsible for the numeric addition operator
&[+] # ditto

&prefix:<++>
&postfix:<++>

# etc
于 2015-07-31T17:02:55.177 回答
7

据我所知，两个版本之间的唯一区别是使用带有隐式$_参数的块而不是使用 What-Star，因此它们确实是等价的。

这是 Perl，所以有不止一种方法可以做到：

*.key
{ .key }
{ $^arg.key }
-> $arg { $arg.key }

>>为什么这种排序在没有超提示的情况下不起作用？

sort将哈希强制转换为对列表，这就是您将得到的：

say %hash.sort(*.key).perl;
# ("one" => "1", "three" => "3", "two" => "2")

要摆脱这些对，您需要遍历列表并调用.kv每个：

say %hash.sort(*.key)>>.kv.perl;
# (("one", "1"), ("three", "3"), ("two", "2"))

say %hash.sort(*.key).map(*.kv).perl;
# (("one", "1"), ("three", "3"), ("two", "2"))

Hash您可以在调用之前强制.kv：

say %hash.sort(*.key).hash.kv.perl;
# ("one", "1", "three", "3", "two", "2")

但这当然会破坏练习的目的，因为不能依赖哈希排序。

您可能已经注意到，根据您编写代码的准确程度，您会得到不同的结果。如果没有尾随.list，您得到的实际上是 aParcel而不是 a List，但语义尚未最终确定。

请注意，即使返回的对象都用简单的括号进行了 perlify，但有些是包裹，有些是列表，您可以通过调用.WHAT. 这仍在进行中。

还要注意其中一些变体中的内括号，您可以通过调用.flat. 如果这样做，您可以使用-> $key, $valuefor 循环的签名，而不是-> ($key, $value)（或者，更明确地说，-> $anon ($key, $value)）使用签名绑定来解包包裹。

除了使用.kv，您可以使用相同的方法来解包 pair 对象：

for %hash.sort(*.key) -> (:$key, :$value) {
    say "'$key' => '$value'";
}
于 2015-07-31T17:05:58.553 回答