6

作为 Ada 的新手，我正在探索它的语法和规则，我想提请注意接下来给出的代码。在这里，我试图设置一个变量 Actual_Stiffness 来保持一个恒定值。它的值由产品给出：

Actual_Stiffness := Stiffness_Ratio * Stiffness_Total

其中 Stiffness_Total 已在规范文件 Material_Data.ads 中定义为常量 Long_Float，而 Stiffness_Total 的值已在广告文件中设置。

WITH Ada.Text_IO;
WITH Ada.Long_Float_Text_IO;
WITH Material_Data;
USE Material_Data;

PROCEDURE sample IS

   Stiffness_Ratio  : Long_Float;
   Actual_Stiffness : CONSTANT Long_Float :=  Stiffness_Ratio * Stiffness_Total;

BEGIN -- main program
   Ada.Text_IO.Put("Enter stiffness ratio: ");
   Ada.Long_Float_Text_IO.Get(Item => Stiffness_Ratio);
   Ada.Long_Float_Text_IO.Put(Item => Stiffness_Ratio);

   --Ada.Text_IO.New_Line;
   --Ada.Long_Float_Text_IO.Put(Item => Actual_Stiffness);
   --Ada.Text_IO.New_Line;
   --Ada.Long_Float_Text_IO.Put(Item => Stiffness_Total);
END sample;

编译时我收到警告消息

警告：“Stiffness_Ratio”可能在它有值之前被引用

在运行程序时，Actual_Stiffness 没有得到正确的值。我可以将 Actual_Stiffness 定义为只是一个 Long_Float（不添加 CONSTANT），然后在我的程序中 BEGIN 之后从产品 Actual_Stiffness := Stiffness_Ratio * Stiffness_Total 中获取其值，此时 Stiffness_Ratio 已经获得了一个值。这将是正确的做法。

我的问题是：

我已将 Stiffness_Total 定义为具有规定值的常量 Long_Float。如何将 Actual_Stiffness 定义为常量（因为它不会在程序中更改），同时保持用户能够在终端以交互方式输入 Stiffness_Ratio 的能力？这甚至可能吗？

非常感谢..

4

2 回答 2

3

由于“Stiffness_Ratio”直到运行时才确定，因此编译器无法按照您的要求在编译时计算“Actual_Stiffness”的值。您必须将“Actual_Stiffness”设为非常量变量，并在“Stiffness_Ratio”有值后使用计算对其进行初始化。（只要刚度比在计算实际刚度时有一个值，您甚至可以将其保留为函数中的常数。）

这是大多数编程语言的标准。

所以，回答你的问题：

  • 不，您不能根据需要将 Actual_Stiffness 定义为常量。

  • 一个适度接近的近似值是您在此过程之外确定 Stiffness_Ratio 值，并将该值作为参数传递到过程中。但是，Actual_Stiffness 仅在手术期间保持不变，而不是一直保持不变。

另一方面，这可能更有用；有人可以在不同时间运行具有多个刚度比值的程序，从而在一次运行中进行许多模拟。

于 2010-07-04T11:50:29.763 回答
2

在 Ada 中，在函数中间声明变量是完全可能且合理的。就像在所有其他编程语言（至少 Java、C、C++、C#、python）中一样，您可以在任何地方显式创建范围：

declare
   A : My_Type := Val;
begin
   Use(A);
end;

这意味着您的常量可以在收到运行时值后声明：

WITH Ada.Text_IO;
WITH Ada.Long_Float_Text_IO;
WITH Material_Data;
USE Material_Data;

PROCEDURE sample IS

   Stiffness_Ratio  : Long_Float;

BEGIN -- main program
   Ada.Text_IO.Put("Enter stiffness ratio: ");
   Ada.Long_Float_Text_IO.Get(Item => Stiffness_Ratio);
   Ada.Long_Float_Text_IO.Put(Item => Stiffness_Ratio);

   --Ada.Text_IO.New_Line;
   declare
      Actual_Stiffness : CONSTANT Long_Float :=  Stiffness_Ratio * Stiffness_Total;
   begin
      Ada.Long_Float_Text_IO.Put(Item => Actual_Stiffness);
   end;
   --Ada.Text_IO.New_Line;
   --Ada.Long_Float_Text_IO.Put(Item => Stiffness_Total);
END sample;

例如，考虑以下欧几里得最大公约数算法的非递归实现：

   function GCD(X,Y : Integer) return Integer is
   begin
      declare
         X : Integer := GCD.X;
         Y : Integer := GCD.Y;
      begin
         while Y /= 0 loop
            declare
               temp : Integer := X;
            begin
               X := Y;
               Y := temp mod Y;
            end;
         end loop;
         return X;
      end;
   end GCD;

在 GCD 内部，参数 X 和 Y 始终是常量，因为它们被声明为in. 这是为了避免混淆；如果我们允许分配给变量，程序员可能会认为他正在引起副作用，就像参数被标记的情况一样out。

John Barnes 在 Ada 2012 中的编程建议在这种情况下在函数本身的范围内声明一个具有不同名称的变量。在第 194 页，第 11.2 节：

   function Sum(List: Cell_Ptr) return Integer is
      Local: Cell_Ptr := List;
      (...)

这使程序员能够引用 List，即常量和未更改的初始值。在上面给出的 GCD 程序的情况下，在循环体中引用该值会导致不正确的行为。

通过添加具有同名变量的内部范围来隐藏 X 和 Y 意味着我们需要显式地包含变量的范围才能犯这个错误。尝试在循环体中更改X := Y为X := GCD.Y，观察 GCD(91,21) 现在返回 21 而不是 7。

最后，请注意，可以通过在标签前面添加名称来为内部范围命名：

   Inner:
   declare
      X : Integer := 0;
   begin
      Use(Inner.X); -- explicitly the X in that scope
   end Inner;
于 2019-12-05T10:00:13.927 回答