6

看起来 libxslt 不支持 XSLT 2.0，并且xsl:result-document. 有没有办法模仿xsl:result-document使用libxslt, 或xsltproc？

4

3 回答 3

14

是的，有，使用exsl:document。一个简单的例子：

==== foo.xsl ====
<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
                xmlns:exsl="http://exslt.org/common"
                extension-element-prefixes="exsl">
  <xsl:output method="html"/>
  <xsl:template match="/">
    <exsl:document href="toc.html" method="html">
      <html>
        <body>
          <xsl:apply-templates select=".//h1"/>
        </body>
      </html>
    </exsl:document>
    <xsl:apply-templates/>
  </xsl:template>
  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

将此作为输入：

==== foo.html ====
<html>
  <body>
    <h1>Hello, world!</h1>
    <p>Some longwinded text follows.</p>
  </body>
</html>

当这样运行时：

xsltproc foo.xsl foo.html

将把它交给标准输出：

<html>
  <body>
    <h1>Hello, world!</h1>
    <p>Some longwinded text follows.</p>
  </body>
</html>

同时也将其写入toc.html：

<html><body><h1>Hello, world!</h1></body></html>
于 2010-07-02T22:31:54.913 回答
3

如果 libxslt 实现EXSLT，那么您可以使用<exsl:document>扩展元素。

如果没有，那么您必须编写自己的扩展函数，因为 XSLT 1.0 不支持创建多个结果文档。

更新：正如此评论中所确认的，libxslt 实现了 EXSLT。只需抓住它并使用<exsl:document>.

于 2010-07-02T18:21:13.717 回答
1

这是一个示例，展示了如何在遍历节点集时使用扩展创建无限数量的文件。同样，使用 xsltproc (libxslt)

示例 XML 输入：

<clients>
    <client id="ACME1" name="ACME Company 1"/>
    <client id="ACME2" name="ACME Company 2"/>
    <client id="ACME3" name="ACME Company 3"/>
</clients>

示例 XSLT：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0" 
                xmlns:exsl="http://exslt.org/common"
                extension-element-prefixes="exsl">

<xsl:output method="html" indent="yes" encoding="UTF-8" />

<xsl:template match="/">
    <xsl:for-each select="/clients/client">
    <exsl:document href="{@id}.html" method="html">
      <html>
        <body>
          <h1>Company: <xsl:apply-templates select="@name"/></h1>
        </body>
      </html>
    </exsl:document>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

会产生3个文件ACME1.html、ACME2.html等。

于 2015-09-06T21:41:01.563 回答