3

我使用 Power Query 提取了上个月测试的所有唯一项目类型：

let
  Source = Sql.Database("XXX", "YYY"),
  dbo_tblTest = Source{[Schema="dbo",Item="tblTest"]}[Data],
  #"Filtered Rows" = Table.SelectRows(dbo_tblTest, each Date.IsInPreviousNMonths([Test_Stop], 1)),
  #"Added Custom" = Table.AddColumn(#"Filtered Rows", "Custom", each Text.Start([Item],5)),
  #"Removed Duplicates" = Table.Distinct(#"Added Custom", {"Custom"})
in
  #"Removed Duplicates"

要得到：

  1. Test_ID --- 项目 --- Test_Start --- Test_Stop --- 自定义
  2. 2585048 --- B1846-6-02 --- 2014 年 1 月 14 日 12:46 --- 2015 年 6 月 25 日 14:28 --- B1846
  3. 2589879 --- B1843-5-05 --- 2013 年 12 月 23 日 16:46 --- 2015 年 6 月 25 日 14:19 --- B1843
  4. 2633483 --- B1907-1-04 --- 2014 年 8 月 21 日 20:47 --- 2015 年 6 月 10 日 6:20 --- B1907
  5. 2638786 --- B1361-2-04 --- 2013 年 6 月 13 日 14:21 --- 2015 年 6 月 16 日 14:15 --- B1361
  6. 2675663 --- B1345-2-02 --- 2014 年 5 月 23 日 18:39 --- 2015 年 6 月 25 日 21:27 --- B1345

接下来，我想使用 Power Query 为 Query1 中列出的每个项目类型提取过去 10 次测试，而不考虑时间段。我想出了如何分别提取过去 10 个项目类型的测试，但不是在一个查询中全部结合在一起。

let
    Source = Sql.Database("XXX", "YYY"),
    dbo_tblTest = Source{[Schema="dbo",Item="tblTest"]}[Data],
    #"Filtered Rows" = Table.SelectRows(dbo_tblTest, each Text.StartsWith([Item], "B1846")),
    #"Sorted Rows" = Table.Sort(#"Filtered Rows",{{"Test_Stop", Order.Descending}}),
    #"Kept First Rows" = Table.FirstN(#"Sorted Rows",10)
in
    #"Kept First Rows"

要得到：

  1. Test_ID --- 项目 --- Test_Start --- Test_Stop --- 值
  2. 11717643 --- B1846-6-02 --- 2015 年 7 月 23 日 12:48 --- 2015 年 7 月 23 日 12:57 --- 43725341
  3. 11716432 --- B1846-1-21 --- 2015 年 7 月 23 日 10:23 --- 2015 年 7 月 23 日 10:29 --- 43724705
  4. 11715802 --- B1846-1-21 --- 2015 年 7 月 23 日 9:28 --- 2015 年 7 月 23 日 10:29 --- 43724720
  5. 11715505 --- B1846-1-21 --- 2015 年 7 月 23 日 8:59 --- 2015 年 7 月 23 日 9:06 --- 43724675
  6. 11715424 --- B1846-1-21 --- 2015 年 7 月 23 日 8:36 --- 2015 年 7 月 23 日 8:59 --- 43724690
  7. 11713680 --- B1846-1-55 --- 2015 年 7 月 23 日 5:50 --- 2015 年 7 月 23 日 6:07 --- 43725239
  8. 11691169 --- B1846-6-04 --- 2015 年 7 月 20 日 22:47 --- 2015 年 7 月 22 日 20:18 --- 43642835
  9. 11690466 --- B1846-6-04 --- 2015 年 7 月 20 日 21:30 --- 2015 年 7 月 22 日 18:41 --- 43642729
  10. 11701183 --- B1846-1-140 --- 2015 年 7 月 21 日 21:34 --- 2015 年 7 月 21 日 22:24 --- 43667358
  11. 11701184 --- B1846-6-04 --- 2013 年 7 月 21 日 20:35 --- 2015 年 7 月 21 日 20:46 --- 43667359

是否可以使用 Power Query 在一个查询中提取所有需要的数据？如果没有，是否可以将 VBA 与 Power Query 一起使用来完成它？

4

1 回答 1

5

在 Power Query 中，如果您正在考虑如何循环，您通常会发现一个高阶库函数可以满足您的需求。在这种情况下，它是分组。

分组按某个键拆分表，在您的情况下是Custom第一个表的列。您可以使用 将“保持超过 10”逻辑重写为您在每个分组表中应用的函数Table.TransformColumns，然后将分组表展开回一个平面表。

您的查询应该是这样的：

let
  Source = Sql.Database("XXX", "YYY"),
  dbo_tblTest = Source{[Schema="dbo",Item="tblTest"]}[Data],
  #"Added Custom" = Table.AddColumn(dbo_tblTest, "Custom", each Text.Start([Item],5)),
  #"Grouped Rows" = Table.Group(#"Added Custom", {"Custom"}, {{"Grouped", each _, type table}}),
  Custom2 = Table.TransformColumns(#"Grouped Rows", {{"Grouped", (groupedTable) =>
      let
          #"Sorted Rows" = Table.Sort(groupedTable,{{"Test_Stop", Order.Descending}}),
          #"Kept First Rows" = Table.FirstN(#"Sorted Rows",10)
      in
          #"Kept First Rows"}}),
  #"Removed Other Columns1" = Table.SelectColumns(Custom2,{"Grouped"}),
  #"Expanded Grouped" = Table.ExpandTableColumn(#"Removed Other Columns1", "Grouped", Table.ColumnNames(#"Added Custom"))
in
  #"Expanded Grouped"
于 2015-07-26T19:58:31.870 回答